How do we take a print out of the current record on the Form?

Let us try this simple method to start with, before using the Form Filter on Report.  We need some sample data, a Form and a Report to try this out.

1. Import the Order details and Products Tables from the Northwind.accdb sample database.
2. Use the Report Wizard and design a Report using the Order Details Table as Record Source (sample report view is given below) and save the Report with the name Rpt_OrderDetails.

   

3. Use the Form Wizard and design a multiple items (continuous) Form using the Order Details Table (sample data view image is given below) and save it with the name Frm_OrderDetails.

   

4. Open the Form Frm_OrderDetails in design view.
5. Select the Command Button Tool from the Toolbox and draw a Command Button on the Header Section of the Form.
6. While the Command Button is still in selected state display the Property Sheet (Design – - >Tools – - > Property Sheet or use F4) and select All Tab on the Property Sheet.
7. Change the Name Property Value to cmdRpt and change the Caption Property Value to Run Report (see the Form image above).
8. Select the Event Tab of the Property Sheet.
9. Select [Event Procedure] from the drop-down list of the On Click event property and  click on the Build (. . .) button at the right edge of the property to open the VBA window with the skeleton of the Command Button Click Event Procedure.
10. Copy and paste the middle line of Code between the existing header and footer lines of the Command Button Click event procedure:

    
    
    Private Sub cmdRpt_Click()
    
       DoCmd.OpenReport "Rpt_OrderDetails", acViewPreview, , "[order id] = " & Me![order id]
    
    End Sub
    

    Check the middle line of the above code. The last parameter to the DoCmd.OpenReport command is a Filter condition to select the current record’s Order ID number to filter all records with the same Order ID number. We have inserted one extra comma between the printing option and the filter condition to skip the choice of using the name of a Query as Report Source Data.

    The filter condition "[Order Id] = " & Me![Order Id] states that take all the records with the current record Order ID Number as source data for the Report.

11. Save the form Frm_OrderDetails and open it in normal view
12. Click on any record with the same Order ID in more than one record or any record you like.
13. Click on the Run Report Command Button to open the Rpt_OrderDetails with the selected record.
14. Close the Report and you may try it again after selecting some other record on the Form.

The above example uses only a single record or several records with the same Order ID to print on the Report. 

Next, we will do it with more flexibility after setting the Filter Property Value of the Form. This can be done after selecting one or more Order IDs for filtering the data on the Form, before we open the Report for printing the data on the Form.  We must set a reference to the Filter Property of the Form replacing the criteria setting we have used earlier: "[order id] = " & Me![order id], on the DoCmd.OpenReport command.  

With this change the user can filter data based on any column value on the Form (like Order Id or Quantity or UnitPrice etc.) and use the result set to print the Report.

1. Make a copy of the form Frm_OrderDetails and paste it with the name Frm_Orderdetails2.
2. Open the form Frm_Orderdetails2 in design view.
3. Click on the Command Button to select and display it’s property sheet (F4).
4. Select  the Event Tab and select the On Click property.
5. Click on the Build (. . .) button to open the VBA window.
6. Copy the following Code and paste replacing the existing lines of code on the Form Module:

   Private Sub cmdRpt_Click()
       If Me.Filter = "" Then
           MsgBox "Apply a filter to the Form first."
       Else
           DoCmd.OpenReport "Rpt_OrderDetails", acViewPreview, , Me.Filter
       End If
   End Sub

7. Check the last parameter setting in the DoCmd.OpenReport statement. We are asking the Report to use whatever criteria setting is available in the current Form’s (Me) Filter Property Value (like ([Order Details].[Order ID] In (30,31,32))) to pick records for the Report. Save the Form and open it in normal view.
8. Click on the Command Button to open the Report.

   You will be greeted with a message asking to ‘Apply a filter to the Form first‘. When you click on the Command Button the program checks whether the Form’s Filter Property is set with a Filter condition or not, like the text we have used in the first example above, or like the sample shown in Step-7 above.

   Note: Remember, once you apply a filter on the form the text of the last filter condition remains saved on the Filter Property.  The Filter action is supported with another property value setting: FilterOn = True/False. When you Toggle the filter action on the Form the FilterOn property value changes but the Filter property value criteria text is not removed. You will be greeted with the above message only when the Filter Property Value is empty.

9. Click on the Order ID column on any record.
10. Click on the Filter Toolbar button (see the image below)to display the Filter selection control.

    

    A list of the selected field values (Order ID numbers) are displayed and shows all the values are check marked, indicating that all the values are in selected state.

11. Click on the Select All Option to de-select all the items.
12. Now, put check marks on the Order ID Numbers 30, 31 & 32 and Click OK to close the Filter Control.

    The form now shows only records of Order ID numbers 30, 31 & 32.

13. Click on the Run Report Command Button on the Header of the Form to open the Report in Print Preview with the records filtered on the Form.
14. Close the Report.
15. Place the cursor on the Quantity Field on any record on the Form.
16. Click on the Filter Toolbar Button to display the Filter Control.
17. Select the items with the Quantity values 100,200 & 300 and click OK button to close the control and filter the records you have selected.
18. Open the Report by clicking on the Run Report Command Button and check the report contents.
19. Close the Report.
20. Click on the Toggle Filter Toolbar button.  The Filter action is reversed and all the records are back on the Form (or the FilterOn Property Value is set as False now).
21. Now, Click on the Run Report Command Button to preview the Report. 

The Report shows the last filtered records only, rather than all the records from the Form.  When we toggle the filter Microsoft Access sets the FilterOn Property Value to False nullifying the effect of the filter action on the form, without removing the filter condition string inserted in the Filter Property, because the User may click the Toggle Filter button again to bring back data filtered by the last set filter condition. Our program keep using it because the Filter Property value is not empty and we are not checking the status of the FilterOn Property setting.

But, we can solve this issue with few changes in our program as follows:

Private Sub cmdRpt_Click()
    If Me.FilterOn Then
        DoCmd.OpenReport "Rpt_OrderDetails", acViewPreview, , Me.Filter
    Else
        DoCmd.OpenReport "Rpt_OrderDetails", acViewPreview
    End If
End Sub

Change the program as shown above and try the effect of the Filter and Toggle Filter action on the Form as well as on the Report.

• Apply Filter to Table directly
• Dynamic Lookup in Query Column
• Creating Water-mark on Ms-Access Reports
• iSeries Date in exported Data
• Change Query Top Values property with VBA

If all Invoices can be saved on disk in separate PDF Files then it is easy to send them through emails to the customers.  This will not only save the cost of stationery but also delivers the invoices to the customers’ mailbox instantly without delay.  Besides that customers can easily view the Invoices on their machines or take printouts at their end, if that become necessary.  In short, part of our tasks are passed on to the customers, saving our time and money.  I don’t think I can stretch it any more.

Let us try this with one or two Tables from the Northwind.mdb sample database.

1. Import the following Tables from the Northwind.mdb (or Access2007 Northwind.accdb) sample database:
   • Order Details
   • Products 

   NB: I will be using Tables from the Northwind.mdb database. But, the queries, Report and Code will be running under Access2007. The Products Table is not used directly in our Query or Report but the ProductID combobox in the Order Details table references this table for product description.

2. Open a new Query in SQL View without selecting any Table/Query from the displayed list.
3. Copy and Paste the following SQL string into the new Query’s SQL editing window and save the Query with the name Invoice_Orders_0:

   SELECT [Order Details].OrderID,
    [Order Details].ProductID,
    [Order Details].Quantity,
    [Order Details].UnitPrice,
    [Order Details].Discount,
    [Quantity]*((1-[Discount])*[UnitPrice]) AS TotalValue
   FROM [Order Details];

4. After saving and closing the above Query create another Query, using Invoice_Orders_0 as source, with the following SQL:

   SELECT Invoice_Orders_0.*
   FROM Invoice_Orders_0
   WHERE (((Invoice_Orders_0.OrderID)=10258));

5. Save the new Query with the name Invoice_Orders_1.
6. Design a Report to print Sales Invoice using Invoice_Orders_1 Query as Record Source.

   Sample Report Design Image is given below:

   

   Sample Report Preview Image is the next one:

   

7. Copy and paste the following VBA Code into a Standard Module and save it:

   Public Function Create_PDF(ByVal OrderStart As Integer, ByVal OrderEnd As Integer, ByVal strPath As String)
   '--------------------------------------------------------------------------------
   'Author : a.p.r. pillai
   'Date   : January 2012
   'Rights : All Rights(c) Reserved by www.msaccesstips.com
   '--------------------------------------------------------------------------------
   'Function Parameters:
   ' 1. - OrderID Start Number
   ' 2. - OrderID End Number
   ' 3. - Target Folder Address, sample: C:\My Documents
   '--------------------------------------------------------------------------------
   Dim strsql_1 As String, strsql As String, criteria As String
   Dim db As Database, rst As Recordset, QryDef As QueryDef
   Dim int_Order As Integer, outFile As String, T As Date
   Dim SQLParam As String, i As Integer, msg As String
   
   'Invoice Query Definition, Order Number must be added at the end as criteria
   strsql_1 = "SELECT Invoice_Orders_0.*  FROM Invoice_Orders_0 "
   strsql_1 = strsql_1 & " WHERE (((Invoice_Orders_0.OrderID)="
   
   'Query definition for Order Numbers between OrderStart and OrderEnd numbers
   SQLParam = "SELECT DISTINCT [Order Details].OrderID FROM [Order Details] "
   SQLParam = SQLParam & "WHERE ((([Order Details].OrderID) Between " & OrderStart & " And " & OrderEnd & ")) "
   SQLParam = SQLParam & " ORDER BY [Order Details].OrderID;"
   
   Set db = CurrentDb
   'open the OrderIDs parameter list to process one by one
   Set rst = db.OpenRecordset(SQLParam, dbOpenDynaset)
   'open the Report Query definition to incorporate OrderID criteria
   Set QryDef = db.QueryDefs("Invoice_Orders_1")
   
   i = 0 'take a count of invoices printed
   Do While Not rst.EOF 'cycle through the parameter list
     'get the order number
     int_Order = Nz(rst!OrderID, 0)
     If int_Order > 0 Then 'if any blank record ignore
        i = i + 1
        'create the criteria part for the Invoice Query
        criteria = int_Order & "));"
        'complete the Invoice SQL by adding the criteria.
        strsql = strsql_1 & criteria
        'Redefine the Invoice Query to print the Invoice
        QryDef.sql = strsql
        db.QueryDefs.Refresh
   
        'PDF file's target path and Order Number is the file name.
        outFile = strPath & "\" & int_Order & ".PDF"
   
        'Save the report as pdf file.
        DoCmd.OutputTo acOutputReport, "Rpt_Invoice", "PDFFormat(*.pdf)", outFile, False, "", 0, acExportQualityPrint
   
     '2 seconds delay loop to give enough time for Access to create the file on disk.
     T = Timer
     Do While Timer < T + 2
       DoEvents
     Loop
    End If
     rst.MoveNext
   Loop
   rst.Close
   
   msg = "Order Start Number: " & OrderStart & vbCr & vbCr
   msg = msg & "Order End Number: " & OrderEnd & vbCr & vbCr
   msg = msg & "Invoices Printed: " & i & vbCr & vbCr
   msg = msg & "Target Folder: " & strPath
   
   MsgBox msg, , "Create_PDF()"
   
   Set rst = Nothing
   Set db = Nothing
   Set QryDef = Nothing
   
   End Function

Now, let us take a look at what preparations we have made so far:

The first Query (Invoice_Orders_0) selects the required fields from Order Details Table for the Customer Invoice Report. Besides that it calculates the Total Value after Discount of each record in the Query. But, in this Query we have not set any criteria to select any specific OrderID  or Range of OrderIDs for printing the Invoices.

We are setting criteria to select specific OrderID in the second Query (Invoice_Orders_1),  created using the earlier Query (Invoice_Orders_0) as Source. The two step query simplifies the SQL and we must take the SQL into the VBA Code to redefine the Query, with changing OrderIDs, so that each OrderId level Invoice is saved in separate PDF file on Disk. 

We have one more Query (the third Query saved in SQLParam String Variable is used directly in the Set rst = db.OpenRecordset(SQLParam, dbOpenDynaset) statement) that is totally confined into the Create_PDF() Function.  When the Create_PDF() Function is called you must give the Order Start Number, Order End Number and Target Folder Address, where the PDF Files are to be saved, as function parameters. The third Query extracts all the Order Numbers within the Start Number and End Number range.  These will be taken one by one to print Invoices in individual files.

NB:  To make this sample exercise simple we are using only the transaction file to print the Invoices.  As you can see from the Report specimen shown above it doesn’t have any Customer Address printed on it.  If this is required then we must consider setting relationships with the Customer Address Table in the Report Query and include the address fields also. The main idea behind this whole exercise is to save the report of individual Invoices in separate pdf files, rather than going into its’ details or refinement.

Keeping that in focus let us continue to review what we are doing in the VBA Code lines.  You must call the Function using the following

Syntax:

Create_PDF  StartNumber,  EndNumber, ”PDF Files Target Folder”)

Example-1:

Create_PDF 10248,10265,”C:\My Documents”

 

Example-2:

 

x = Create_PDF(10248,10265,”C:\My Documents”)

 

You may call the function from a Command Button Click Event Procedure, after setting the Parameter values in Text Boxes on the Form

Example-3:

Create_PDF Me![txtSNumber], Me![txtENumber], Me![txtPathName]

With the Start Number and End Number values the Parameter Query is redefined to extract all the Order Numbers between those two numbers from the Order Details Table so that they can be used for extracting Order-wise items for printing individual Invoices.  The SELECT DISTINCT clause suppresses duplicates from the parameter list.

The data source of Rpt_Invoice Report is Invoice_Orders_1 Query. This is redefined for each OrderId as criteria for printing the Rpt_Invoice in PDF format.  The PDF files are saved in the location specified as third parameter C:\My Documents.

Each line in the VBA Code is commented to indicate what it does in each step, please go through them to understand the code better.

Key Words:PDF Files, Invoice, Report, Access2007

• Dynamic Lookup in Query Column
• Creating Water-mark on Ms-Access Reports
• iSeries Date in exported Data
• Change Query Top Values property with VBA
• Creating Animated Command Buttons
  Technorati Tags: Utility

What is the solution if we need different sequence numbers for the records that we create on each day?

For example, assume we are working on a Hospital Project and patients getting registered in the hospital on a particular day should have a unique Registration Card Number consisting of current date and a three digit sequence number in the format: yyyymmdd000. The sequence number must reset to 001 when the date changes.

If the Hospital maintains history records of the patients in physical files, organized by Date, Month and Year-wise order it is easy for them to locate any file with the Registraion Card Number.

We can generate this number automatically with a Function.  Let us try it with a sample Table and Form.

Before that copy and paste the following Function Code into a Standard VBA Module and save it:

Public Function Autonum(ByVal strField As String, ByVal strTable As String) As String
Dim dmval As String, dt1 As String, dt2 As String, Seq As Integer, dv As String

'get the highest existing value from the table
dmval = Nz(DMax(strField, strTable), 0)

'if returned value is 0 then the table is new and empty
'create autonumber with current date and sequence 001
If Val(dmval) = 0 Then
   dv = Format(Now(), "yyyymmdd") * 1000 + 1
   Autonum = dv
   Exit Function
End If

'format the number as an 11 digit number
dv = Format(dmval, "00000000000")
'take the 3 digit sequence number separately
Seq = Val(Right(dv, 3))
'take the date value separately
dt1 = Left(dv, 8)
'get today's date
dt2 = Format(Now(), "yyyymmdd")
'compare the latest date taken from the table
'with today's date
If dt1 = dt2 Then 'if both dates are same
   Seq = Seq + 1 'increment the sequence number
   'add the sequence number to the date and return
   Autonum = Format(Val(dt1) * 1000 + Seq)
   Exit Function
Else 'the dates are different
   'take today's date and start the sequence with 1
   Autonum = Format(Val(dt2) * 1000 + 1)
End If

End Function

1. Create a sample Table with the following Structure, as shown in the image given below:

   

2. The CardNo Field is a text type with 11 characters in length.  Both second and third fields are also text fields with sizes 10 and 50 characters respectively.
3. Save the Table with the name Patients.
4. Use the Form Wizard to design a Datasheet Form for the Patients Table and name the Form as frm_Patients.
5. Open the Form in Design View.
6. Click on the CardNo Field to select it.
7. Display the Property Sheet (F4). If you are using Access2007 then you can select CardNo from the Selection Type drop-down list.
8. Select the Data Tab and set the following Property Values as shown below:
   • Enabled = Yes
   • Locked = Yes
9. Access2007 users select Form from the Selection Type drop-down control. Earlier version users click on the top left corer of the Form (in the intersection where a black rectangle is shown) to ensure that the Property Sheet belongs to the Form and not of any other control on the Form.
10. Select the Event Tab on the Property Sheet.
11. Select the Before Insert  event property and select Event Procedure from the drop-down list.
12. Click on the Build (. . .) button to open the VBA Module of the Form.
13. Copy the middle line of the following procedure and paste it in the middle of the empty Form_BeforeInsert() lines of Code in the Form module.

    Private Sub Form_BeforeInsert(Cancel As Integer)
      Me![CARDNO] = Autonum("CardNo", "Patients")
    End Sub

14. Save the Form frm_Patients with the changes made.
15. Open the form in normal view and type Mr. in the Title Field and type some name in the Patient Name field.  You can see that the first field is filled with current date in yyyymmdd format and the sequence number 001 as suffix.
16. Type few more records.  Since, we have locked the CardNo field Users cannot edit this field’s contents. Sample image is given below:

1. Now, we will test whether the sequence number resets to 001 or not when the date changes. To do that first close the frm_Patients Form.
2. Open the Patients Table directly in Datasheet View.
3. Change the 7th and 8th digit from left (the dd digits of the date) to previous date in all the records that you have entered so far. 
4. For example: if the date displayed is 20120109001 then change it to previous day like: 20120108001.
5. When you have completed changing all the records close the Table.
6. Open the Form frm_Patients in normal view and try adding few more records on the Form. 

Tip:  If you prefer to test it on different dates on next few days you may do so rather than changing the dates and trying it now itself.

You can see that the Sequence number at the end of the CardNo resets to 001 with current date and subsequent records’ last three digits gets incremented automatically. 

The user cannot change the CardNo manually because we have set the Locked Property Value of the field to Yes.  Since, the Enabled Property Value also set to Yes the User can select this field and search for a specific CardNo, if needed.

If you would like to display the sequence number part separate from the date with a dash, (like: 20120109-005) we can do that by changing the Input Mask Property of the field, without affecting how it is recorded on the table.

1. Open the frm_Patients in Design View.
2. Click on the CardNo field to select it.
3. Display the Property Sheet (F4) of the Field.
4. Type 99999999-999;;_ in the Input Mask Property. 

   Tip: When you set the input mask this way the dash character between the date and sequence number is never stored in the table, it is used for display purposes only.  But, if you enter a 0 between the two semi-colons like 99999999-999;0;_ then the dash character also will be stored in the CardNo field on the table.  It is better if we don’t do that.

5. Save the Form and open it in normal view.  Now you can distinguish the date and sequence number very easily.

Assume that a Patient approaches the registration desk with her Registration Card, the staff member at the desk should search for the patient’s record with the CardNo to retrieve her history record, to know the location of her personal file, to know which doctor the patient attended last etc.  You have two search options when the search control is displayed. 

Try the following:

1. Click on the CardNo field to select it.
2. Press Ctrl+F to display the search control (search control image is given below).

As shown on the image above you can search for the CardNo without the dash if you remove the check mark from the search option Search Field as Formatted.  Put the check-mark on when searched with the dash separating date and sequence number.

• Creating Water- mark on Ms-Access Reports
• iSeries Date in exported Data
• Change Query Top Values property with VBA
• Creating Animated Command Buttons
• Data Change Monitoring

Before running that function the user has to spot some text to search for and then run the function with that search text as parameter. The utility function searches for the text, with .Find() method of the Module Object, to find the search text and select that line within the target Function/Sub-Routine.  Based on the selected line we can read other details of the function/sub-routine, like total number of lines within that function/sub-routine, function header line number and function ending line number.  These parameters must be available to insert the error handling lines in appropriate locations within the procedure.

If there are several functions or sub-routines to insert error handling lines then this method takes some time to cover all of them, one by one.

Here, we will look at a different version of the same function that scans through the entire Module and inserts error handling lines in all of the Functions/Sub-Routines at one go.

Before that,

Links to the earlier Articles are given below, just in case if you would like to take a look at the simple methods of the Module Object we have tried earlier:

Write VBA Code with VBA

VBA Module Object and Methods

Prepare a list of Procedure Names from a Module

Utility for inserting VBA Error Handler Code

The new function is much simpler to use.  Copy and paste the following Code into a new Standard Module and save it:

Public Function ErrorTrap(ByVal str_ModuleName As String)
On Error GoTo ErrorTrap_Error
'--------------------------------------------------------------
'Program : Inserting Error Handler Lines automatically
'        : in a VBA Module
'Author  : a.p.r. pillai
'Date    : December, 2011
'Remarks : All Rights Reserved by www.msaccesstips.com
'--------------------------------------------------------------
'Parameter List:
'1. strModuleName - Standard Module or Form/Report Module Name
'--------------------------------------------------------------

Dim objMdl As Module, x As Boolean, h As Long, i As Integer
Dim w As Boolean, lngR As Long, intJ As Integer, intK As Integer
Dim linesCount As Long, DeclLines As Long, lngK As Long
Dim str_ProcNames(), strProcName As String, strMsg As String
Dim start_line As Long, end_line As Long, strline As String
Dim lng_StartLine As Long, lng_StartCol As Long
Dim lng_EndLine As Long, lng_EndCol As Long, procEnd As String
Dim ErrHandler As String, lngProcLineCount As Long
Dim ErrTrapStartLine As String, lngProcBodyLine As Long

Set objMdl = Modules(str_ModuleName)

linesCount = objMdl.CountOfLines
DeclLines = objMdl.CountOfDeclarationLines
lngR = 1
strProcName = objMdl.ProcOfLine(DeclLines + 1, lngR)
If strProcName = "" Then
   strMsg = str_ModuleName & " Module is Empty." & vbCr & vbCr & "Program Aborted!"
   MsgBox strMsg, , "ErrorTrap()"
   Exit Function
End If
strMsg = strProcName
intJ = 0

'Determine procedure Name for each line after declaraction lines
For lngK = DeclLines + 1 To linesCount

  'compare procedure name with ProcOfLine property
  If strProcName <> objMdl.ProcOfLine(lngK, lngR) Then
     'increment by one
     intJ = intJ + 1
     'get the procedure name of the current program line
     strProcName = objMdl.ProcOfLine(lngK, lngR)
  End If
Next lngK

ReDim str_ProcNames(intJ)

strProcName = strMsg: intJ = 0
str_ProcNames(intJ) = strProcName
For lngK = DeclLines + 1 To linesCount
  'compare procedure name with ProcOfLine property

  If strProcName <> objMdl.ProcOfLine(lngK, lngR) Then
     'increment array index by one
     intJ = intJ + 1
     'get the procedure name of the current program line
     strProcName = objMdl.ProcOfLine(lngK, lngR)
     str_ProcNames(intJ) = strProcName

  End If
Next

For intK = 0 To intJ
    ErrHandler = ""
    ErrTrapStartLine = ""
    'Take the total count of lines in the module including blank lines
    linesCount = objMdl.CountOfLines

    strProcName = str_ProcNames(intK) 'copy procedure name
    'calculate the body line number of procedure
    lng_StartLine = objMdl.ProcBodyLine(strProcName, vbext_pk_Proc)
    'calculate procedure end line number including blank lines after End Sub
    lng_EndLine = lng_StartLine + objMdl.ProcCountLines(strProcName, vbext_pk_Proc) + 1

    lng_StartCol = 0: lng_EndCol = 150
    start_line = lng_StartLine: end_line = lng_EndLine

    'Check for existing Error Handling lines in the current procedure
    x = objMdl.Find("On Error", lng_StartLine, lng_StartCol, lng_EndLine, lng_EndCol)
    If x Then
         GoTo NxtProc
    Else
     'Create Error Trap start line
         ErrTrapStartLine = "On Error goto " & strProcName & "_Error" & vbCr
    End If

    ErrHandler = vbCr & strProcName & "_Exit:" & vbCr

    lngProcBodyLine = objMdl.ProcBodyLine(strProcName, vbext_pk_Proc)

    'Set procedure start line number to Procedure Body Line Number
    lng_StartLine = lngProcBodyLine
    'calculate procedure end line to startline + procedure line count + 1
    lng_EndLine = lng_StartLine + objMdl.ProcCountLines(strProcName, vbext_pk_Proc) + 1

    'Save end line number for later use
    'here lng_endline may include blank lines after End Sub line
    lngProcLineCount = lng_EndLine

    'Instead of For...Next loop we could have used the .Find() method
    'but some how it fails to detect End Sub/End Function text
    For h = lng_StartLine To lng_EndLine
      strline = objMdl.Lines(h, 1)
      i = InStr(1, strline, "End Sub")
      If i > 0 Then
          'Format Exit Sub line
          ErrHandler = ErrHandler & "Exit Sub" & vbCr & vbCr
          lngProcLineCount = h 'take the correct end line of End Sub
          h = lng_EndLine + 1
          GoTo xit
      Else
         i = InStr(1, strline, "End Function")
         If i > 0 Then
          'Format Exit Function line
          ErrHandler = ErrHandler & "Exit Function" & vbCr & vbCr
          lngProcLineCount = h 'or take the correct endline of End Function
          h = lng_EndLine + 1
          GoTo xit
        End If
      End If
xit:
    Next

   'create Error Handler lines
   ErrHandler = ErrHandler & strProcName & "_Error:" & vbCr
   ErrHandler = ErrHandler & "MsgBox Err & " & Chr$(34) & " : " & Chr$(34) & " & "
   ErrHandler = ErrHandler & "Err.Description,," & Chr$(34) & strProcName & "()" & Chr$(34) & vbCr
   ErrHandler = ErrHandler & "Resume " & strProcName & "_exit"

  'Insert the Error catch start line immediately below the procedure header line
   objMdl.InsertLines lngProcBodyLine + 1, ErrTrapStartLine

 'Insert the Error Handler lines at the bottom of the Procedure
 'immediately above the 'End Function' or 'End Sub' line
   objMdl.InsertLines lngProcLineCount + 2, ErrHandler

NxtProc:
Next

strMsg = "Process Complete." & vbCr & "List of Procedures:" & vbCr
For intK = 0 To intJ
  strMsg = strMsg & "  *  " & str_ProcNames(intK) & "()" & vbCr
Next
MsgBox strMsg, , "ErrorTrap()"

ErrorTrap_Exit:
Exit Function

ErrorTrap_Error:
MsgBox Err & " : " & Err.Description, , "ErrorTrap()"
Resume ErrorTrap_Exit
End Function

You can run this function from the Debug Window or from a Command Button Click Event Procedure.  Sample run Syntax on Standard Module:

ErrorTrap “Module Name”

Example-1:

ErrorTrap "Module3"

Module3 will be scanned for Procedure Names and each procedure is checked for the presence of existing Error Handling lines.  If ‘On Error Goto’ statement is encountered anywhere within a procedure then that procedure is skipped and goes to the next one to check.

To run on Form or Report Module use the following Syntax:

ErrorTrap "Form_FormName"

Example-2:

ErrorTrap "Form_Employees"

Example-3:

ErrorTrap "Report_Orders"

When the ErrorTrap() function completes working with a module it displays the list of procedures found in that Module. Sample run image is given below:

If you run the ErrorTrap() Program on a Form/Report that doesn’t have a VBA Module ( or its Has Module Property value is set to No) then a Subscript out of Range message is displayed and the program will be aborted.

It is better if you save this Program in your Library Database and link the Library Database to your Project.  Visit the Link: Command Button Animation for details on how to use a database as a Library Database with your own Custom Functions.

I tried to take the ErrorTrap() Function one step further to scan through the entire database Modules and insert error trap routines in all of them, saving each module immediately after changes.  But, Access2007 keep crashing every time and finally I have discarded the idea.  Besides, the above function gives the User more control to review the module subjected to this function for any kind of side effects.

I have test run this function several times and found ok, but field testing may be required under different environment to detect logical errors.  If you find any such errors please give me a feed back through the comment section of this page.  Review each module immediately after running this function for accuracy and use it at your own risk. 

• iSeries Date in exported Data
• Change Query Top Values property with VBA
• Creating Animated Command Buttons
• Data Change Monitoring
• Continued on Page-2 on Report

Flash Card Courtesy: www.123greetings.com

History of Christmas

On December 25, Christians traditionally celebrate the birth of Christ. The origins of the holiday are uncertain, however by the year 336, the Christian church in Rome observed the Feast of the Nativity (birth) on December 25. Christmas also coincided with the winter solstice and the Roman Festival of Saturnalia.

Christmas Tinsel

Around 1610, tinsel was first invented in Germany made from genuine silver. Machines were invented that shredded silver into thin tinsel-sized strips. Silver tinsel tarnishes and loses its shine with time, eventually, artificial replacements were invented. The original inventor of tinsel remains unknown.

Candy Canes

Candy Canes: The origin of the candy cane goes back over 350 years, when candy-makers both professional and amateur were making hard sugar sticks. The original candy was straight and completely white in color.

Artificial Christmas Trees

Towards the end of the 1800′s, another variation of the traditional Christmas tree appeared: the artificial Christmas tree. Artificial trees originated in Germany. Metal wire trees were covered with goose, turkey, ostrich or swan feathers. The feathers were often died green to imitate pine needles.

In the 1930′s, the Addis Brush Company created the first artificial-brush trees, using the same machinery that made their toilet brushes! The Addis ‘Silver Pine’ tree was patented in 1950. The Christmas tree was designed to have a revolving light source under it, colored gels allowed the light to shine in different shades as it revolved under the tree.

Christmas Cards

Englishman, John Calcott Horsley popularize the tradition of sending Christmas greeting cards, in the 1830s.

Source – Hallmark Archives: www.hallmark.com/online/

Now, we are going to write a very useful Utility Program for inserting general Error Handler Code Lines into VBA Functions or Sub-Routines automatically. Let us take a look at the Error Trap Routine that we normally write in a Sub-Routine to take care of unexpected errors and to exit the program gracefully, without stopping the code and giving trouble to the User in the middle of normal operations.

Private Sub cmdRunReport_Click()
On Error Goto cmdRunReport_Click_Error
.
.
.
.
cmdRunReport_Click_Exit:
Exit Sub

cmdRunReport_Click_Error:
MsgBox Err & " : " & Err.Description,,"cmdRunReport_Click()"
Resume cmdRunReport_Click_Exit

End Sub

The blue colored lines are the Error Handler Lines and the dotted area will hold the actual program.  Normally, we concentrate on writing code for the actual action we intended to execute within the procedure (the dotted line area) and the Error Handler part can wait for later finishing touches stage.  File handling programs or areas where validation checks are performed gets more attention in setting up error trap routines.

Our idea is to insert the Error Handler lines at the beginning and end of the program automatically.  Any serious program that you will write needs these lines of code and writing them manually everywhere will take some of your valuable time in a busy schedule.  If you left out some of your programs without adding the Error Handler lines earlier, you can add them now very easily with the Utility Program that we are going to write.

As you can see in the above code that the lines suffixed with _Exit:, _Error: etc. have the program name attached to them like cmdRunReport_Click_Exit: and these values are taken from the Sub-Routine or Function Names.  The first line of the error handler will be inserted immediately after the Program Name and other lines at the end of the Program.  So we must know few details about the program before we are able to insert the Error Trap Lines into appropriate locations in the program.  For that we must address few Property Values of any line of code located within the Function or Sub-Routine and get the property values from the Module Object.

To make it more clear let us draw out a plan for our program as below:

1. First, search for some unique text within the VBA Module, located within our target Function or Sub-Routine.  For this we can use the .Find() method of the Module Object.
2. Once the search stops on the target line within the Function or Sub-Routine we can read several details of the program we are in now.  The .Find() method not only finds the target line of our program with the search text but also the program line number within the Module (all the lines within a Module is sequentially numbered including blank lines), the Column Number at which the search text starts, which column the search text ends etc.  The Find() method Syntax is as given below:

Modules(ModuleName).Find strSearchText, lngStart_Line, lngStart_Column, lngEnd_line, lngEnd_Column, [[WholeWord], [MatchCase], [PatternSearch]]

Sample Code:

Set mdl = Modules("Form_Employees")

With mdl
  .Find “myReport”, lngStart_Line, lngStart_Column, lngEnd_line, lngEnd_Column, False
End With

• The first parameter is the search text to find.
• The next four parameters tells from where to start and where to stop looking for the search text.  For example, you want to search for the second occurrence of the text “myReport” located somewhere beyond line number 25 then you will set lngStart_Line=25.  If “myReport” is in Docmd.OpenReport “myReport” then the lngStart_Column value can be about 10 or leave it as 0 to start searching from beginning of the line.  Once the search text is located by the Find() method all four variables will be loaded with the search text related values as below:
  • lngStart_Line = line number on which the search text is located.
  • lngStart_Column = Column Number (or first character of the search text starts on which character position from left)
  • lngEnd_Line = Line on which the Search Text found and search stoped.
  • lngEnd_Column = Column on which the search text ends.
• Once the search text is located on a line the lngStart_Line and lngEnd_line will refer to the same program line on which the search text is located.  The start and end column values will be loaded into lngStart_Column and lngEnd_Column variables.
• When the search operation is successful we can extract several information related to that program line to use for working within that particular Function or Sub-Routine. We will read the following information of a particular program to insert the Error Handler lines of Code at appropriate locations in the Program:
  • Get the Program Name from the .ProcOfLine Property (or in expanded form Procedure name Of the Line we found through search) of the program line.
  • Get the Procedure Body Line Number from the .ProcBodyLine Property. The line number on which the program Private Sub cmdRunReport_Click() starts. This line number + 1 is the location where we can insert the first line (On Error Goto label statement) of Error Handler.
  • Get the Number of Lines in this particular procedure we are in, from .ProcCountLines Property.  Even though this is a useful information this has some draw backs.  If there are blank lines above the procedure Name or below the End Sub or End Function line (if it is the last procedure in a Module then it can have blank lines at the end) they are also included in the count.  So we must take corrective action or take alternative measures to take correct values.
• Once the above information is available we can write the Error Handler lines into String Variables and use the .InsertLines() method of the Module Object to place them in the beginning and end of the procedure.

1. Open the VBA Editing Window (ALT+F11).
2. Insert a new Standard Module.
3. Copy and Paste the following VBA Code into the Module and Save it:

Public Function ErrorHandler(ByVal strModuleName As String, _
                                ByVal strSearchText As String, _
                                Optional ByVal lng_StartLine As Long = 1)
On Error GoTo ErrorHandler_Error
'--------------------------------------------------------------------------------
'Program : Inserting Error Handler Lines automatically
'        : in VBA Functions or Sub-Routines
'Author  : a.p.r. pillai
'Date    : December, 2011
'Remarks : All Rights Reserved by www.msaccesstips.com
'--------------------------------------------------------------------------------
'Parameter List:
'1. strModuleName - Standard Module or Form/Report Module Name
'2. strSearchText - Text to search for within a
'   Function or Sub-Routine
'3. lng_StartLine - Text Search Start line Number, default=1
‘Remarks: Standard/Form/Report Module must be kept open before running this Code
'--------------------------------------------------------------------------------
Dim mdl As Module, lng_startCol As Long
Dim lng_endLine As Long, lng_endCol As Long, x As Boolean, w As Boolean
Dim ProcName As String, lngProcLastLine As Long
Dim ErrTrapStartLine As String, ErrHandler As String
Dim sline As Long, scol As Long, eline As Long, ecol As Long
Dim lngProcBodyLine As Long, lngProcLineCount As Long
Dim lngProcStartLine As Long, start_line As Long, end_line As Long

Set mdl = Modules(strModuleName)
lng_startCol = 1
lng_endLine = mdl.CountOfLines
lng_endCol = 255

With mdl
    .Find strSearchText, lng_StartLine, lng_startCol, lng_endLine, lng_endCol, False
End With

'lng_StartLine - line number where the text is found
'lng_StartCol  -  starting column where the text starts
'lng_EndCol    - is where the search text ends
'lng_EndLine   - end line where the text search to stop
'if search-text is found then lng_StartLine and lng_EndLine will
'point to the same line where the search-text is found
'otherwise both will be zero

If lng_StartLine > 1 Then
  'Get Procedure Name.
  'The vbext_pk_Proc system constant
  'dictates to look within a Function or Sub Routine
  'Not to consider Property-Let/Get etc.
   ProcName = mdl.ProcOfLine(lng_endLine, vbext_pk_Proc)

   'Get Procedure Body Line Number
   lngProcBodyLine = mdl.ProcBodyLine(ProcName, vbext_pk_Proc)

   'Look for existing Error trap routine, if any
   'if found abort the program
   sline = lngProcBodyLine: scol = 1: ecol = 100: eline = lng_endLine
   x = mdl.Find("On Error", sline, scol, eline, ecol)
   If x Then
      MsgBox "Error Handler already assigned, program aborted"
      Exit Function
   End If

 'Get Line Count of the Procedure, including
 ' blank lines immediately above the procedure name
 'and below, if the procedure is the last one in the Module
   lngProcLineCount = mdl.ProcCountLines(ProcName, vbext_pk_Proc)

 'Create Error Trap start line
   ErrTrapStartLine = "On Error goto " & ProcName & "_Error" & vbCr
 'Compose Error Handler lines
   ErrHandler = vbCr & ProcName & "_Exit:" & vbCr

'determine whether it is a Function procedure or a Sub-Routine
'lng_StartLine = lng_endLine:
lng_startCol = 1: lng_endCol = 100: lng_endLine = lngProcBodyLine + lngProcLineCount
'save the startline and lng_EndLine values
start_line = lng_StartLine: end_line = lng_endLine

'Check whether it is a Function Procedure or a Sub-Routine
w = mdl.Find("End Function", lng_StartLine, lng_startCol, lng_endLine, lng_endCol, False)

If w Then 'Function Procedure
   'Take correct procedure line count excluding
   'blank lines below End Sub or End Function line
   lngProcLineCount = lng_StartLine
   ErrHandler = ErrHandler & "Exit Function" & vbCr & vbCr
Else
   lng_StartLine = start_line: lng_endLine = end_line: lng_startCol = 1: lng_endCol = 100
   w = mdl.Find("End Sub", lng_StartLine, lng_startCol, lng_endLine, lng_endCol, False)
   If w Then 'Sub-Routine
     lngProcLineCount = lng_StartLine
     ErrHandler = ErrHandler & "Exit Sub" & vbCr & vbCr
   End If
End If
   'create Error Handler lines
   ErrHandler = ErrHandler & ProcName & "_Error:" & vbCr
   ErrHandler = ErrHandler & "MsgBox Err & " & Chr$(34) & " : " & Chr$(34) & " & "
   ErrHandler = ErrHandler & "Err.Description,," & Chr$(34) & ProcName & "()" & Chr$(34) & vbCr
   ErrHandler = ErrHandler & "Resume " & ProcName & "_exit"

  'Insert the Error catch start line immediately below the header line
   mdl.InsertLines lngProcBodyLine + 1, ErrTrapStartLine

 'Insert the Error Handler lines at the bottom of the Procedure
 'immediately above the 'End Function' or 'End Sub' line
   mdl.InsertLines lngProcLineCount + 2, ErrHandler

End If

ErrorHandler_Exit:
Exit Function

ErrorHandler_Error:
MsgBox Err & " : " & Err.Description, , "ErrorHandler()"
Resume ErrorHandler_Exit

End Function

Since, this program itself is a Coding aide you must keep the target Module (Standard/Form/Report) open before running this program to insert the Error Handling code segment into the target Function/Sub-Routine.

You may call the ErrorHandler() Function from the Debug Window or from a Command Button Click Event Procedure as shown below:

'The third parameter is optional, you may omit it
ErrorHandler "Form_Employees","myReport",1

This will start searching for the text myReport from the beginning of the Employees Form Module, stops within the program where the search finds a text match and inserts the Error Handling Code lines at the beginning and end of the program.

If the text ‘myReport’ appears in more than one Function/Sub-Routine in the Module then you must give the third parameter (Search start line number) to start searching for the text beyond the area wherever exclusion is required. Example:

'Look for text 'myReport' from line 20 onwards only
ErrorHandler "Form_Employees","myReport",20

When the ErrorHandler() Function is run, first it will look for the presence of existing error handling lines starting with ‘On Error’ and if found assumes that the error handling lines are already present in the Function/Sub-Routine and stops the program after displaying the following message:

‘Error Handler already assigned, program aborted.’

Comment lines are added for clarity above the program lines explaining what happens next. 

If you find any logical error in the program please give me feed back through the comment section of this page. To protect from spam we insist on joining the site before you are able to post comments.

• Change Query Top Values property with VBA

Earlier Articles:

1. Writing Code with VBA.
2. Uploading Code from external Text File into a Module.

We have seen how to insert a cmdButton_Click() Event Procedure into a Form Module using the .InsertLines() method of the Module Object in the first Articlle and how to upload the same program from a Text File with the .AddFromFile() method of the Module Object in the second Article.

In this example, we will try to prepare a list of Procedures from a Standard Module and from a Class Module.  Here, we will learn the usage of the following Properties of the Module Object:

 With Modules(strModuleName):
   lng_BodyLines = .CountOfLines ‘ Total Number of lines of Code in the Module
   lng_LinesAtGobalArea = .CountOfDeclarationLines ‘Takes a count of lines in the Global declaration area
   str_ProcedureName = .ProcOfLine(LineNumber, NumberOfLines) ‘indexed list of Code lines with their Procedure names
 End with 

The .ProcOfLine (stands for Procedure Name of the current line of VBA Code) is an indexed list and we must provide the index number of the Code line under process to check which procedure that the code line belongs to.  The second index value is normally one, if you are inspecting a line by line basis. If you prefer to check two or more lines together then change this number accordingly.

The Pseudo Code of the VBA Program we are going to write is given below.

1. Take Count of Code Lines of the Module, Standard Module or Class Module.
2. Take Count of Global Declaration Lines.
3. First Procedure Name  =  Count of Global declaration Lines + 1
4. Array(0) = First Procedure Name. Saves the Function/Sub-Routine name into an Array.
5. Scan through the remaining lines of code:

     A)   Check the .ProcOfLine property value for the Procedure Name of the current line of Code.

     B)  If the Procedure Name of the current line is same as of previous line then go to C)

              Else save the current Code line’s Procedure Name in the next element of Array().

     C)  Move to the next Code line and if End-of-lines reached then go to D) else repeat from A)

     D)  Create a string with the Procedure Names from the saved Array.

     E)  Display the list of Procedures in a Message Box.

     F)  End of Program.

Now let us write our VBA Code for the above program.

Public Function ListOfProcs(ByVal strModuleName As String)
'------------------------------------------------------
'Courtesy : Microsoft Access
'------------------------------------------------------
Dim mdl As Module
Dim linesCount As Long, DeclLines As Long
Dim strProcName As String, lngR As Long, intJ As Integer
Dim str_ProcNames() As String, lngK As Long
Dim strMsg As String

Set mdl = Modules(strModuleName)
'Total Count of lines in the Module
linesCount = mdl.CountOfLines

'Take the count of Global declaration lines
DeclLines = mdl.CountOfDeclarationLines
lngR = 1

'The first line below the declaration lines
'is the first procedure name in the Module
strProcName = mdl.ProcOfLine(DeclLines + 1, lngR)
'Re-dimension the str_ProcNames() Array for a single element
'and save the procedure name in the Array.
intJ = 0
ReDim Preserve str_ProcNames(intJ)
str_ProcNames(intJ) = strProcName
'Determine procedure Name for each line after declaraction lines
For lngK = DeclLines + 1 To linesCount
'compare current Code-line’s procedure name with earlier line’s name
 ‘if not matching then we have encountered a new procedure name
 If strProcName <> mdl.ProcOfLine(lngK, lngR) Then
 'increment array index by one
 intJ = intJ + 1
 'get the procedure name of the current program line
 strProcName = mdl.ProcOfLine(lngK, lngR)
 'Redimension the array for a new element by
 'preserving the data of earlier elements
 ReDim Preserve str_ProcNames(intJ)
 'Save the procedure name in the array
str_ProcNames(intJ) = strProcName
 End If
Next lngK
 'create the list of Procedure Names from Array to display
strMsg = "Procedures in the Module: " & strModuleName & vbCr
For intJ = 0 To UBound(str_ProcNames)
 strMsg = strMsg & str_ProcNames(intJ) & vbCr
Next
 MsgBox strMsg
End Function 

Copy and paste the above program into a Standard Module and save it.

To display a list of procedures from a Standard Module, display the Debug Window (Ctrl+G) and type the following command with a standard Module name as parameter like the sample given below and press Enter Key:

ListOfProcs "Utility_Local"

Sample run display of Procedure Names in a MsgBox is shown below:

To take listing of procedures from a Form or Report Module use the following Syntax:

ListOfProcs "Form_myFormName"

or

ListOfProcs "Report_myReportName"

Sample run output from a Form Module.

• Creating Animated Command Buttons
• Data Change Monitoring
• Continued on Page-2 on Report
• Product Group Sequence with Autonumbers
• Invoke Word Mail-Merge from Access2007

I don’t say that the frm.Module.CreateEventProc() method, that we have tried, was an easy approach to write a one line statement in a Form Module.  But, trying something different is always exciting in programming like exploring the unknown.  After all, it is there as part of the Application to explore and learn. 

Today we will try an alternative and simple method for the same example we have tried last week.  That is to write all the program lines in a text file and load that program directly into the Form Module.

If you have tried last week’s example we can use the same ‘Sample’ Form for today’s trial run,  or do the following to get prepared:

1. Open a new Form in Design View.
2. Create a Command Button on the Detail Section of the Form.
3. While the Command Button is in selected state display it’s Property Sheet (F4 or ALT+Enter).
4. Change the Name Property Value to cmdRun and the Caption Property Value to Run Report.
5. Save the Form with the name Sample.
6. If you have last week’s Sample form then open it in Design View.
7. Display the Form Module, remove the existing program lines and save the Form.
8. Open Notepad, copy and paste the following program lines into Notepad and save it as c:\windows\temp\vbaprg.txt:

   Private Sub cmdRun_Click()
       DoCmd.OpenReport "myReport", acViewPreview
   End Sub

9. Replace the report name "myReport" with one of your own Report Name from the database.
10. Open a Standard VBA Module, copy and paste the following main program into the Standard Module:

    Public Function LoadFromTextFile()
    Dim frm As Form, frmName As String, ctrlName As String
    
    frmName = "Sample"
    'ctrlName = "cmdRun"
    
    'Open the form in design view
    DoCmd.OpenForm frmName, acDesign
    
    'define the form object
    Set frm = Forms(frmName)
    
    'call the form's Module Object's AddFromFile() method
    'to read the program from the text file
    'and insert them into the Form Module
    frm.Module.AddFromFile "c:\windows\temp\vbaprg.txt"
    
    'Save and close the form with the code
    DoCmd.Close acForm, frmName, acSaveYes
    
    'Open the form in Normal view
    DoCmd.OpenForm frmName, acNormal
    
    End Function

11. Place the cursor in the middle of the Code and press F5 to run the Code.
12. Press ALT+F11 to display the Database window with the Sample Form open.
13. Click on the Command Button to open the Report in print preview.
14. Close the Report.
15. Change the Sample Form in Design View.
16. Open the form module and check for the program lines we have loaded from the vbaprg.txt file.

• Data Change Monitoring
• Continued on Page-2 on Report
• Product Group Sequence with Autonumbers
• Invoke Word Mail-Merge from Access2007
• Copy Paste Data from Excel to Access2007

Sample opening and closing statements of Form_Current() Event Procedure is shown below:

Private Sub Form_Current()

End Sub

Let us do it differently this time by programming a Command Button Click event procedure automatically through VBA. We are going to insert a Command Button Click Event Procedure in a Form Module with the help of a Function Write_Code().  We learned something similar through an earlier Article on the topic: Creating Animated Command Button with VBA. 

In this trick, the Command Button is programmed automatically to open a Report in Print Preview.  Following are the lines of VBA Code we are going to insert into the Form Module automatically:

Private Sub cmdRun_Click()
    DoCmd.OpenReport "myReport", acViewPreview

End Sub

1. Open a new blank Form in Design View.
2. Add a Command Button control on the Form.
3. While the Command button is in selected state display it’s Property Sheet (F4 or ALT+Enter).
4. Change the Name Property Value to cmdRun.
5. Change the Caption Property Value to Run Report.
6. Save and close the Form with the name frmSample.
7. Open VBA Editing Window (ALT+F11) and insert a new Standard Module. You can toggle between Database and VBA Windows with ALT+F11 Keyboard shortcut.
8. Copy and Paste the following Code into the Standard Module and save it:

   Public Function Write_Code(ByVal frmName As String, ByVal CtrlName As String)
   Dim frm As Form, x, txt As String, ctrl As Control
   
   DoCmd.OpenForm frmName, acDesign, , , , acHidden
   Set frm = Forms(frmName)
   Set ctrl = frm.Controls(CtrlName)
   With ctrl
       If .OnClick = "" Then
          .OnClick = "[Event Procedure]"
       End If
   End With
   
   x = frm.Module.CreateEventProc("Click", ctrl.Name)
   
   txt = "DoCmd.OpenReport " & Chr$(34) & "myReport" & Chr$(34) & ", acViewPreview"
   frm.Module.InsertLines x + 1, txt
   
   DoCmd.Close acForm, frmName, acSaveYes
   DoCmd.OpenForm frmName, acNormal
   
   End Function

9. Replace the Report name "myReport" with one of your own Report name in the program line: txt = "DoCmd.OpenReport " & Chr$(34) & "myReport" & Chr$(34) & ", acViewPreview".
10. Display the Debug Window (Ctrl+G).
11. Type the following line in the Debug Window and press Enter Key:

    Write_Code "frmSample","cmdRun"

    Form’s name "frmSample"  is passed as first parameter to the Write_Code() Function and Command Button’s name "cmdRun" is as second parameter.

12. Press ALT+F11 to display the Database window.  You can see that frmSample is already open in normal view after inserting the program lines in it’s VBA Module.

13. Click on the Command Button to open your Report in Print Preview with the cmdRun_Click() Event Procedure.  You may change the Form View into Design View, open the Form Module and check the lines of Code we have inserted in there.

At the beginning of the above program the OnClick Event Property is checked, for the presence of any programmed action of the Command Button (cmdRun), and inserts the text "[Event Procedure]" in the property in preparation for writing the program lines in the VBA Module.

In the next step the Form Module’s .CreateEventProc() method is called to create the Click Event Procedure of the Command Button: cmdRun.  If you want a Double-Click Event procedure, rather than a Click() event procedure, then change the word "Click" to "dblClick".

Replace the DoCmd.OpenReport. . . statement with appropriate Code for other actions like MouseMove.

You can call the Write_Code() function from a Command Button click event procedure on a Form.  Create two Text Boxes on the Form, enter the Form Name and Control Name in them and use the text box names in both parameters of the Write_Code() function.

• Continued on Page-2 on Report
• Product Group Sequence with Autonumbers
• Invoke Word Mail-Merge from Access2007
• Copy Paste Data from Excel to Access2007
• User-level Access Security and Access2007

The above question was raised in an MS-Access Discussion Forum on the Net.  The user tried a similar set of the sample code given below (with one of the three lines inter-changeably) on the Page2_Click() Event procedure to move the focus to the "Ship City" Field on the tab page, but none of those lines worked, why?:

Private Sub Page2_Click()
     Forms!frm_Main![Ship City].SetFocus
     frm_MainMenu![Ship City].SetFocus
     me.[Ship City].SetFocus
End Sub 

Tab-Control is an interesting piece of Object to use on a Form. I have used this control mainly for building form based Menus with List Boxes on them. You can find a sample image of a Control Screen below with List box based Menus on it:

In the middle of the Control Form shows a list as a menu of choices.  In fact there are fifteen different set of menus displayed there.  They are displayed one over the other by clicking on a set of Command Buttons, shown on either side of the list box.  You can learn this trick from here.

Coming back to the topic, first thing that you should know is that when you click on the Tab-Page Button (see the sample image below) on a Tab-Control the Click Event procedure will not be fired.

This will happen only when you click somewhere on the body of the Tab-Page.  So you need two clicks, one click on the Tab-Page button to make that page contents visible followed by another click on the body of the Tab-Page to run the Page2_Click() Event Procedure so that whatever Code you put in the procedure is executed.  This is not an attractive proposition, but we will take an alternative route to do it with a single-click.

If you have already visited the above text links that I have suggested then you are armed with few ideas and you are already ahead of me on what I am going to say here. 

We will implement the following ideas for a single click solution:

1. Create separate Command Button for each Tab-Page with one line of VBA Code to make it current or visible.
2. On the second Command Button click event procedure we will add one more line of code to move the focus to a particular text box at the middle of the tab-page.
3. Since, we have Command Buttons to display Tab Pages we will hide the Tab-Page Buttons of the Tab-control. Optionally, change the Tab-control’s back-style design transparent to make the tab control’s border design invisible.

Before going into the detail design of the above steps I can give you a very simple solution, if you are not interested to go into all the fancy work. Set the Tab Index Property Value of the Text box (like [Ship City]) to 0 (zero).

Don’t mix up Tab Index with Tab Control and Tab Page.  When you tap on the Tab-Key on the Keyboard the cursor jumps from one control (Text Box, Combo box, Check-box etc.) to the next based on the Tab Index Property Value setting on those controls.

This value is sequentially numbered from 0 to the number of such controls on a Form.  This is automatically set sequentially in the order in which you place the controls on the form at design time manually or through Form Wizards.  When a Form is open the control with Tab Index value 0 will get focus by default, irrespective of it’s physical placement on the form.

So, if the [Ship City] Field is not the starting point on your form and you want to make it so then do the following:

1. Open the Form in design view.
2. Click on the [Ship City] field to select it.
3. Display it’s Property Sheet (F4 or ALT+Enter).
4. Find the Tab Index Property and change the Value to 0.  Other controls’ Tab Index Property values will be automatically changed by Access.  You must review and change them, if needed, to bring them to the desired order.

NB:  Each Tab Page is like a separate sub-form and have separate set of Tab Index sequence numbers starting with zero on them, even if you place different group of fields of the current record.

Now, you are already armed with an easy solution, you may be interested to learn some fancy trick on the Tab Control programming too.

A database can be filled with data very easily.  Any Tom, Dick and Harry can build a database to do that, with whatever easy method available to him.  If it is for his own use then no issues.  But, when it is presented to a Client/User it should have an impressive appearance and should be user-friendly.  Besides that it gives you a chance to advertise your professionalism in your work too.

Coming back to the topic, we will now take the first three steps of action, we have defined above, for a different approach to solve the problem.  A sample design of a Form, with a Tab Control with three pages to hold different group of information from the Orders Table of Northwind.accdb sample database.  You may use any table you like for designing a similar Form, with three Command Buttons at the left side of the Tab Control for trial run:

1. Click on the first Command Button to select it.
   • Display it’s Property Sheet (F4 or ALT+Enter keys).
   • Change the Name Property Value to cmdOrder and change the Caption property value to Order Details.
   • Click on the Event Tab of the Property  Sheet, select On Click Event property, select [Event Procedure] from the drop-down control.
   • Click on the Build ( . . . ) button to open the Form’s VBA Module with an opening and closing statements of a program.
   • Copy and paste the following lines of Code, over-writing the existing lines, or simply copy the middle line alone and paste it between the opening and closing statements of the program:

     Private Sub cmdOrder_Click()
       Me.TabCtl0.Pages(0).SetFocus
     End Sub

2. Similarly change the middle Command Button’s Name Property Value to cmdShipper and Caption Property Value to Shipper Details.
   • Follow the last three steps mentioned above to copy paste the following Code for the middle Command Button Click Event Procedure:

     Private Sub cmdShipper_Click()
       Me.TabCtl0.Pages(1).SetFocus
       Me.Ship_City.SetFocus
     End Sub

     In the first line code we have changed Tab page reference .Page(0) to .Page(1) that refers to the second page of the Tab Control.  Here we have added one more line Me.Ship_City.SetFocus to move the insertion point (cursor) to the “Ship City” field, wherever it is physically placed.  So, with one click on the Command Button will select the second page of the Tab Control and will set the focus on the Ship City field too.

     We are addressing the control (Me.Ship_City.SetFocus) as if it is directly placed on the form surface rather than as a child control on the Tab Page.  Remember, each group of fields on each Tab Page have separate set of Tab Index sequence numbers starting from 0, to move the cursor around on that page.

     So, if you set the reference of the “Ship City” field as a child control on Tab Page2, like Me.TabCtl0.Pages(1).Controls("Ship City").SetFocus, it is equally valid.

3. Change the last Command Button’s Name Property Value to cmdPayment and Caption Property Value to Payment Details.
   • Copy paste the following lines of Code for the last Command Button Click Event Procedure, as you did for the earlier two cases:

     Private Sub cmdPayment_Click()
        Me.TabCtl0.Pages(2).SetFocus
     End Sub

4. Save the Form and open it in normal view. When you open the form, by default Page1  of the tab control will be active.
5. Click on the middle Command Button. You can see the second page of the Tab Control become active and the control "Ship City" field is in focus now.
6. Click on the Payment Details Command Button to select the third page. You may try all the command buttons repeatedly to get the feel of their usage.

   Since, our command buttons took over the function of Tab-Pages of the Tab Control Object we don’t need the Tab Control Page buttons above and we will remove immediately.

7. Change the Form Mode into Design View.
8. Click on the Tab Control by clicking on the right side of the Page3 button.
9. Display the Property Sheet (F4).
10. Click on the All tab of the property sheet and set the Style Property Value to None from the drop-down list.

    If you open the Form in normal view the Tab Control will look like the image given below, without the Tab Page indicators. Clicking on the Command Buttons will turn the Pages as before. You can do a magic trick by completely hiding the Tab Control’s identity marks by setting the Back Style Property Value to Transparent.

    

11. Change the form to design view (if the form is in normal view) and change the Back Style Property Value to Transparent.
12. Save the Form and open it in Normal View.

    No sign of the Tab Control now, except displaying the controls on the first Tab Page with their values and labels. Click on the Command Buttons one after the other. You will find that the data fields and their labels appear from nowhere occupying the same area every time, like magic.

• Product Group Sequence with Autonumbers
• Invoke Word Mail-Merge from Access2007
• Copy Paste Data from Excel to Access2007
• User-level Access Security and Access2007
• Macro and Temporary Variables

But, can we manage without directly linking them to the FE?  For example; can we create a Query in the current database using an external Table (not a linked table) from another MS-Access database?

This topic we have already discussed earlier and proved that it is possible.  Check the following Blog Posts to learn this trick on different types of external data sources:

1. Opening External Data Sources
2. Opening dBase Files directly
3. Opening Excel Database directly
4. Display Excel Values directly on Form
5. Database Connection String Properties
6. Source ConnectStr Property and ODBC
7. Link External Tables with VBA
8. Lost Links of External Tables
9. MS-Access Live data in Excel
10. MS-Access Live data in Excel-2

As you can see from the above list that serial number 1 to 6 methods are used for bringing external data into Access in different ways without keeping them linked to the Access Database.  When working with dBase or Foxpro Tables, the path to the Folder, where the dBase/Foxpro Table is located stands as the database name.

If you have gone through the second Article Opening dBase Files directly then you already know what we are going to explore here and have a general idea by now as how to send output data into external databases without linking them to MS-Access.

Before going into that let us take a closer look at the sample SQL that brings in data from a dBase Table through a Query, without linking the table into MS-Access database.

NB:  If you don’t have a dBase Table, to try out these examples, you can create dBase Tables by exporting one or more of your Access Tables into a separate Folder on your disk.  You don’t have to install dBase Application on your machine. Necessary ODBC Driver Files are already installed by MS-Office in your machine.

SELECT Employees.* FROM Employees IN 'C:\MydBase'[DBASE IV;];

The SELECT Query will return the entire records from the Employees.dbf Table from the dBase database ‘C:\MydBase’.  The text  [DBASE IV;] is the database type and version indicator.  The SQL IN ‘C:\MydBase’[DBASE IV;]; clause creates a direct link to the Employees.dbf Table without a physical link.  That means the Employees.dbf data is available to other processes through this query only.

Through out the above articles we were discussing about bringing data in from external databases without keeping them linked to the Access.  This time we will explore how to update or add data into the external databases.

A sample SQL that updates an external dBase Table is given below:

UPDATE Products IN 'C:\MydBase'[DBASE 5.0;] SET Products.TARGET_LEV = 45
WHERE (((Products.TARGET_LEV)=40) AND ((Products.REORDER_LE)=10));

With the above SQL we are updating the Products stock Target level to 45 from 40, for items with Re-order Level (Minimum Stock Level) is 10 and current stock quantity target level is 40.

Let us append some data from Products_Tmp Table from the current MS-Access Database to the Products.dbf Table of C:\MydBase dBase Database.  The sample SQL is given below:

  INSERT INTO Products
  SELECT Products_Tmp.*
  FROM Products_Tmp IN 'C:\MydBase'[DBASE 5.0;];

Let us examine the Property Sheet of one of the above Queries to check for any indication about the SQL IN Clause setting is in there or not?

1. Open one of the above Queries in Design View.
2. Display the Property Sheet of the Query. Press F4 or ALT+Enter to display the property sheet and make sure that it is the Query Property Sheet. Below the Title of the Property Sheet there will be a description: Selection Type Query Property.
3. You may click on an empty area to the right of the Table on the Query Design surface to make sure that the Property Sheet displayed is Query’s Property Sheet, not the Table or Query Column Property Sheet. Check the sample image given below.
   

   

4. Check the Source Database and Source Connect Str Property Values. If you find it difficult to memorize the correct syntax of the IN Clause in the SQL then you can populate the respective values in these properties of the Query as shown. This will automatically insert the Connection String with correct syntax in the SQL.

You can find correct syntax for Access, Excel, Paradox and ODBC connection string for IBM iSeries machine, SQL Server etc. from the above quoted Articles.

A Word of Caution:

Even though the above methods provide some convenient way to manage external tables, without keeping them permanently linked to MS-Access database, extensive use of this method can lead to issues at a later stage, if you are not careful. It is important that you maintain some form of documentation of these Queries for safe keep.

What kind of issues?

Let us take the example of an external MS-Access database itself. The SQL given below appends some data into the Employees table in another Microsoft Access database on LAN Server directly. This is a routine process done daily or weekly etc.

INSERT INTO Employees IN 'T:\Sales\mdbFolder\Database1.accdb'
SELECT Employees_tmp.*
FROM Employees_tmp;

Everything works just fine and you forgot about this specific Query or other Queries similar to this one. After about six month’s time you thought of shifting or copying the databases from the current location into another Folder on Server (say T:\Export\mdbFolder), leaving a copy in the old . . .\Sales\. . . folder as backup, and installed in the new . . .\Export\. . . folder. Everything found working OK without triggering any error in the new location and the Users are also happy.

Your database have few Queries with the above Connection Strings in their SQL, which never crossed into your mind of attending to them and to change the SQL to point them correctly to the databases on the new location. The Queries will keep on servicing the Table in the old location . . .\Sales\. . . , instead of the Table in . . .\Export\. . . location. The data missing problem when reported by the user may not trigger the Query IN Clause button in your mind immediately and you may be pulling your hair to find out what went wrong, wasting hours or days, till you arrive at the accident spot.

In spite of these draw-backs it is a good way to use the external databases when needed only, if the frequency is minimal, rather than keeping them always attached to the FE. 

• Invoke Word Mail-Merge from Access2007
• Copy Paste Data from Excel to Access2007
• User-level Access Security and Access2007
• Macro and Temporary Variables
• Easy-read Reports

This is only for users of Microsoft Access 2003 or earlier version databases implemented with Microsoft Access Security. You can use earlier version databases in Access2007 or in Access 2010 without converting them. I am not yet upgraded to Access2010.

You can run the Workgroup Administrator program from Access2007 to link to the Workgroup Information File (.mdw). Please refer the Article: Running Workgroup Admin Program from Access2007 for details.

Frankly speaking, I am not happy with the idea of frequent changes of versions, irrespective of what advantages they provide. It is true that I am really excited to learn new features, but not on the cost of what we have already learned and implemented. I still wonder why the Menus and Toolbars are jumbled around and presented them with fancy names like Ribbons in Access2007. These kind of changes will only add to the confusion and waste of time to find out things we are already familiar in earlier version.  By the time users are out of the woods with the new changes they are slapped with a new version and start all over again looking for things, which were in easy reach earlier.

Upgrades are good if draw-backs and bugs of earlier Versions are corrected and implemented with real enhancements, which users can find them easily. 

Coming back to the topic of taking print out of Users and Groups, there is an option already available in Access.  The only problem is that the listing will be dumped directly to the Printer.

To use this option select Tools – - > Security – - > Users and Group Accounts – - > Users – - > Print Users and Groups.  

In Microsoft Access2007, open a database of Access2003 or earlier version first, then select Database Tools – - > Administer – - > Users and Permissions – - > User and Group Accounts . . . – - > Users – - > Print Users and Groups.

But, why you should waste stationery when you have a better option?  You can create a list of Users and Groups in a Text file and save it on your disk with the VBA Program given below.  Copy and paste the following Code into a Standard Module and save it:

Public Function UsersList()
'-------------------------------------------------------------
'Author : a.p.r. pillai
'Date   : Oct 2011
'Rights : All Rights Reserved by www.msaccesstips.com
'Remarks: Creates a list of Users & UserGroups from the
'       : active Workgroup Information File and saves
'       : the list into a text file: UserGroup.txt
'       : in the current database path
'-------------------------------------------------------------
Dim wsp As Workspace, grp As Group, usr As User
Dim fs As Object, cp_path As String
Dim a, txt
Const ten As Integer = 10 

cp_path = CurrentProject.Path
Set wsp = DBEngine.Workspaces(0)
'Create a Text file: UserGroup.txt with FileSystemObject
Set fs = CreateObject("Scripting.FileSystemObject")
Set a = fs.CreateTextFile(cp_path & "\UserGroup.txt", True) 

'Write headings
a.writeline "SYSTEM-DEFAULT GROUPS"
a.writeline "-----------------------"
a.writeline ("User-Groups  User-Names")
a.writeline ("-----------  ----------") 

'List Default Admins & Users Group First
For Each grp In wsp.Groups
   txt = grp.Name
   If txt = "Admins" Or txt = "Users" Then
     a.writeline txt & Space(ten - Len(grp.Name)) & Space(3) & "..."
     For Each usr In grp.Users
        txt = Space(Len(grp.Name) + (ten - Len(grp.Name))) & Space(3) & usr.Name
        a.writeline txt
     Next: a.writeline crlf
   End If
Next 

'Groups, except Default Admins & Users
a.writeline "ADMINISTRATOR-DEFINED GROUPS"
a.writeline "----------------------------"
a.writeline ("User-Groups  User-Names")
a.writeline ("-----------  ----------") 

For Each grp In wsp.Groups
   txt = grp.Name
   If txt = "Admins" Or txt = "Users" Then
      GoTo nextitem
   Else
      a.writeline txt & Space(ten - Len(grp.Name)) & Space(3) & "..."
      For Each usr In grp.Users
         txt = Space(Len(grp.Name) + (ten - Len(grp.Name))) & Space(3) & usr.Name
         a.writeline txt
      Next: a.writeline crlf
   End If
nextitem:
Next
a.Close
'Open UserGroup.txt file with the list User list.
Call Shell("Notepad.exe " & CurrentProject.Path & "\UserGroup.txt", vbNormalFocus) 

End Function

You can run the Code directly from the Debug Window or from a Command Button Click on a Form.  The Text File will be created in the current database folder with the name UserGroup.txt and it will be opened in Windows Notepad automatically. 

Whenever you run this program the earlier file will be over-written.  You may rename the file for safe keep.

The result of a sample run of the program is given below:

If you need a print out of Users and Groups then you may print it from the text file.

• Copy Paste Data from Excel to Access2007
• User-level Access Security and Access2007
• Macro and Temporary Variables
• Easy-read Reports
• Top N Records in Query

I made an attempt here to put the main elements of Microsoft Access Security elements together into the form of a picture so that we will get a general idea as what all components are involved and where they are all kept for implementing Microsoft Access Security.  

It is important to regulate Users’ roles and maintain security of data, integrity of various objects and VBA Code.

We already have several Articles discussing Microsoft Access Security. You can access these articles from the Security Sub-Menu from the Main Menu Bar on this site.

Microsoft Access Security can be divided into two parts:

1. The first part of the Security elements (Workgroup File Id elements and User/Group Names, Personal IDs and Passwords), which resides within the Workgroup Information File. 
2. Object level access rights information which resides within the Database, forms the second part.

When both parts are combined, consisting of fourteen pieces of security elements, becomes the full security key of a User.  See the Diagram given below:

The first three elements: Workgroup Name, Organization & Workgroup Id forms the unique Workgroup Information File identification elements. You must keep these information in a safe place, after creating the Workgroup Information File.  If you somehow got lost this file you must give these specific information to create this Workgroup Information File again.  MS-Access distinguishes one Workgroup Information File from the other using this unique information.

The next three elements: User or Group Name, Personal ID & Password are User specific information.  Group Account have only Group Names and Personal IDs, no passwords.  It is very important that you keep a record of the User/Group Names and their Personal ID information in a safe place.

The Group Security Account is only a means of organizing Users into different groups so that their access privileges can be assigned at Group level.  The Users inherits the access privileges assigned to the Users’ Group Account when they are added to the Group.

When you create a new Workgroup Information File, by default there will be only one User Account: Admin and two Group Accounts: Admins & Users .  The Admin User account is a member of the Admins & Users Group Accounts.  You cannot delete these two Group Accounts and any new User Account you create will be a member of the Users Group Account by default.  You cannot delete the Admin User Account either but it can be removed from the Admins Group Account as part of a security measure.

Members of the Admins Group have full administrative power to assign permissions to Objects and transfer ownership of objects (except the Database Object) to other User/Group accounts.

Here, one important aspect you have to keep in mind is that the Owner of the Database (the User who created the Database)/Object have equal privileges of an Administrator, a member of the Admins Group Account.  The Owner of an object can assign permissions, like an administrator, for other Users or transfer his ownership of the object to another User.  

Ownership of a Database Object cannot be transferred to anybody.  But, one who likes to take the ownership of a Database, he must create a new database and import all the objects (if, he has enough privileges to do that) into the new Database.

• User-level Access Security and Access2007
• Macro and Temporary Variables
• Easy-read Reports
• Top N Records in Query
• Attachment field in Access2007

When we open a form with a Table or Query as Record Source the Form when loaded opens a parallel recordset in memory with unique bookmarking of each record. We can search through this virtual recordset in memory without directly touching the actual Table or Query. But, when we add or update a record in this virtual recordset that change is saved in the actual table. We call this virtual recordset as the RecordsetClone of the Form.

Sample VBA Code given below shows how to address the Form’s RecordsetClone to find a record based on some criteria.

Private Sub FindPID_Click()
'Find Record matching Product ID
Dim m_find, rst As Recordset

'validation check of search key value
m_find = Me![xFind]
If IsNull(m_find) Then
   Me.FilterOn = False
   Exit Sub
End If

'validation check of search key value
If Val(m_find) = 0 Then
  MsgBox "Give Product ID Number..!"
   Exit Sub
End If

'Find a record that matches the ProductID
'and make that record current using the recordset bookmark.
If Val(m_find) > 0 Then
   Set rst = Me.RecordsetClone 'declare the recordset of the form
   rst.FindFirst "ProductID = " & m_find
   If Not rst.NoMatch Then '<if record found then make that record current
      Me.Bookmark = rst.Bookmark
   End If
   rst.Close
End If

End Sub

We have a Blog Post on Data search and filter on Form through the above code. If you would like to take a look at it then click here.

In the above example we were using the RecordsetClone Object of the Main Form on the main form module itself. But how do we address the RecordsetClone Object of the Sub-Form, from Main-Form, to update the current recordset on the Sub-Form. Here, what we have to keep in mind is that the records, which appears on the Sub-Form Datasheet View, are related to the current record on the Main-Form and only those records can be accessed for whatever operation we planned to do on them. Not all the records of the Record Source Table/Query.

On the Main Form, all records of the Record Source Table/Query can be accessed through the RecordsetClone object, for search or update operation. But, the RecordsetClone of the sub-form will have only those records displayed on the sub-form, related to the current record on the main-form.

Let us try an example to learn how to access the sub-form recordset from the main form and update records.

1. Import the following two Tables from the Northwind.accdb (or Northwind.mdb) database:
   • Orders
   • Order Details
2. Open the Order Details Table in design view.

3. Add a new field: SaleValue with Data Type Number and Field Size Double.
4. Save the Order Details Table with the new field
5. Design the Main form for Orders Table in column format.

   If you have used the Form Wizard and created a Split Form then delete the Datasheet sub-form or table (Access2007). Display the Property Sheet of the Form, find the Default View property, change the Split Form value to Single Form.

6. Design a Datasheet Sub-Form for Order Details Table.
7. Expand the Footer of the Sub-Form and create a Text box there.
8. Change the Name Property value to TotSale.
9. Write the expression =Sum([SaleValue]) in the Control Source property.
10. Save and close the Form with the name: Order Details.
11. Insert the Order Details sub-form in the Detail Section of the Orders Form below the Orders Form controls. See the image given below:

    

12. While the Sub-Form is still in selected state display it’s Property Sheet (F4).
13. Change the Link Master Field Property Value to Order ID.
14. Change the Link Child Field Property Value to Order ID.
15. Add a Command Button above the sub-form as shown on the design above.
16. Display the Property Sheet of the Command Button (F4 or Alt+Enter.
17. Change the Name property value to cmdUpdate
18. Select the On Click Event property and select [EventProcedure] from the drop-down list.
19. Click on the Build (. . .) Button at the right end of the property to open the VBA Module of the Form.
20. Copy and Paste the following VBA Code into the VBA Module overwriting the skeleton lines of the Sub-Routine there.

    Private Sub cmdUpdate_Click()
    Dim rst As dao.Recordset
    Dim m_UnitPrice As Double
    Dim m_Discount As Double
    Dim m_Quantity As Long
    Dim m_SaleValue As Double
    
    'Address the recordset on the Sub-Form [Order Details]
    Set rst = [Order Details].Form.RecordsetClone
    rst.MoveFirst
    Do While Not rst.EOF
        m_UnitPrice = rst![Unit Price]
        m_Discount = rst![Discount]
        m_Quantity = rst![Quantity]
        m_SaleValue = m_Quantity * ((1 - m_Discount) * m_UnitPrice)
        rst.Edit
        rst![SaleValue] = m_SaleValue
        rst.Update
        [Order Details].Form.Bookmark = rst.Bookmark
    rst.MoveNext
    Loop
    rst.Close
    
    Set rst = Nothing
    
    End Sub

21. Create a Text box to the right of the Command Button.
22. Change the Caption of the Child Label to Order Value:
23. Write the expression =[Order Details].[Form]![totSale]. The idea of this expression is to bring the Summary Value from the Text box, we have created in the Footer Section of the sub-form, into the Order Form.
24. Save and close the Orders Form.
25. Open the Orders Form in normal View.
26. If the SaleValue column is not appearing in the visible area of the Datasheet then move the bottom scrollbar to the right, highlight the SaleValue column, click and hold the mouse button and drag it to the left and place it into the visible area.

    You can now see the Sub-Form shows some records related to the Order ID on the main Form. The new Text box we have created to the right of the Command Button is empty because we have not updated the [SaleValue] field on the datasheet.

27. Click on the Command Button to calculate and update the Sale Value of each record on the Datasheet Sub-Form.

Now you will find the Sale Value column of all records on the sub-form updated and the Summary value of all records appearing in the Text box to the right of the Command Button. The records updated are only those Order Details records related to Order Id on the Orders Form. If you move the Orders record forward their related record sale value is not updated. They will be updated only when you click on the Command Button.

The statement in the above code Set rst = [Order Details].Form.RecordsetClone is setting a reference to the RecordsetClone Object of the Sub-Form [Order Details]. Subsequent lines calculates the Sale Value after Discount, if any, and updates the sale value into the new field [SaleValue] we have created in the Order Details Table.

The statement [Order Details].Form.Bookmark = rst.Bookmark overwrites the form’s Bookmark with the recordset’s current record Bookmark. The result of this action is that the current record processed in the recordset clone become current record on the sub-form. If you have several records on the sub-form you can see some visible action on the sub-form moving the cursor from one record to other very fast, starting from the first record to the last one-by-one as the updating action progress through the records.

• Macro and Temporary Variables
• Easy-read Reports
• Top N Records in Query
• Attachment field in Access2007
• Embedded Macros in Access2007

Finally, that day has come and you have got Microsoft Access2007 installed on your machine.  Started exploring the new interfaces to get a feel of things in the new version.

After a few days you are uncomfortable with the whole set up.  Don’t know where to locate Menus and Toolbar buttons (new name Ribbon) you were so familiar with earlier version of Access.  You suddenly realizes that design tasks of Forms and Reports are not going to be as easy as before, at least till you are familiar and comfortable with the new version of Access.

I know, you are ready to take any possible help from anybody to get going.  I think Microsoft also knows about your hardships and they have something for you to get around this issue, provided if you know what to look for in Access2003. 

There is an Excel Workbook: accessmaps.xls with Access2003 and Access2007 Menus and Toolbar Options side-by-side.  You can select the Access2003 Menus in Worksheets File, Edit etc. and at the left side locate menu options of Access2003 and at the right column you will find the corresponding Access2007 option, easy?

Well then, find the accessmaps.xls file and save a copy where you can find it easily, probably on your desktop.

Do the following to get the file:

1. Click on the Access Help button (the circular button with a white question mark in blue background at the right end of the Menu Bar).  Microsoft Access Help window opens.
2. Click on the Getting started option, under the Table of Contents, to open the sub-topics.
3. Find Reference: Locations of Access 2003 commands in Access 2007 and click on it to open the details page at the right window.
4. Click on New locations of familiar commands hyperlink to send you to the bottom of the document or use the vertical scroll bar to move to the bottom of the document.
5. Click on the Access Ribbon mapping workbook and a File Download dialog box  opens up asking whether you want to open or save the accessmaps.xls file.
6. You better save a copy on your Desktop so that whenever you want it you can find it easily.

• Easy-read Reports
• Top N Records in Query
• Attachment field in Access2007
• Embedded Macros in Access2007
• Attachment Field in Access2007

IIf Function Returns one of two parts, depending on the evaluation of an expression.

Syntax: IIf(expr, truepart, falsepart)

The IIf function syntax has these named arguments:

Part	Description
expr	Required. Expression you want to evaluate.
truepart	Required. Value or expression returned if expr is True.
falsepart	Required. Value or expression returned if expr is False.

Remarks

IIf always evaluates both truepart and falsepart, even though it returns only one of them. Because of this, you should watch for undesirable side effects. For example, if evaluating falsepart results in a division by zero error, an error occurs even if expr is True.

Example

This example uses the IIf function to evaluate the TestMe parameter of the CheckIt procedure and returns the word "Large" if the amount is greater than 1000; otherwise, it returns the word "Small".

  Function CheckIt(TestMe As Integer)
      CheckIt = IIf(TestMe > 1000, "Large", "Small")
  End Function 

Courtesy: Microsoft Access Help

Let us expand the above function to check a series of expressions to return one of the values among them.

  Function CheckIt(TestMe As Integer)
      CheckIt = IIF(TestMe > 0 AND TestMe < 256, "Byte",IIF(TestMe > 255 AND TestMe < 32768,"Integer","Large"))
  End Function 

As you can see from the above example that for testing of each expression we have to nest the IIF() function one within another, when two or more expressions are evaluated, and it is absolutely necessary that the parentheses are pared properly.  This is where we face problems while using this function in Query columns or in criteria rows etc.

If we need a valid value to be returned when none of the expressions evaluated to True (in the above example the text "Large") then IIF() is the correct solution, otherwise we have alternative function Switch().

The Switch() Function is very simple to use without nesting of expressions like IIF().  Let us rewrite the CheckIt() Function with Switch() function to see how simple it is.

  Function CheckIt(TestMe As Integer)

      CheckIt = Switch(TestMe > 0 AND TestMe < 256, "Byte",TestMe > 255 AND TestMe < 32768,"Integer")

  End Function

The above function does the same work but if none of the expressions evaluated to True then the result returned in CheckIt variable is Null instead of the text “Large”.  If you want to check the returned result for Null and replace Null with the text “Large” then rewrite the expression as below:

CheckIt = NZ(Switch(TestMe > 0 AND TestMe < 256, "Byte",TestMe > 255 AND TestMe < 32768,"Integer"),"Large")

OR

x = Switch(TestMe > 0 AND TestMe < 256, "Byte",TestMe > 255 AND TestMe < 32768,"Integer")

CheckIt = Nz(x,”Large”)

If you are using the Switch() Function in a Query column or criteria row then the first example must be used with Switch() enveloped in Nz(). 

I think it is easier and compact to use Switch() Function when compared with IIF() that needs repeating the function name IIF with balancing of several parenthesis when several expressions are evaluated.

Usage in a sample Query:

UPDATE Employees SET Employees.Designation = Switch(Employees.Designation IS NULL,'UNKNOWN')
WHERE ((Employees.FirstName IS NOT NULL));

See the Switch() Function definition is given below for details, taken from Microsoft Access Help Document.

Switch Function Evaluates a list of expressions and returns a Variant value or an expression associated with the first expression in the list that is True.

Syntax

Switch(expr-1, value-1[, expr-2, value-2 … [, expr-n,value-n]])

The Switch function syntax has these parts:

Part	Description
expr	Required. Variant expression you want to evaluate.
value	Required. Value or expression to be returned if the corresponding expression is True.

 

Remarks

The Switch function argument list consists of pairs of expressions and values. The expressions are evaluated from left to right, and the value associated with the first expression to evaluate to True is returned. If the parts aren’t properly paired, a run-time error occurs. For example, if expr-1 is True, Switch returns value-1. If expr-1 is False, but expr-2 is True, Switch returns value-2, and so on.

Switch returns a Null value if: None of the expressions is True. The first True expression has a corresponding value that is Null. Switch evaluates all of the expressions, even though it returns only one of them. For this reason, you should watch for undesirable side effects. For example, if the evaluation of any expression results in a division by zero error, an error occurs.

Example

This example uses the Switch function to return the name of a language that matches the name of a city.

Function MatchUp (CityName As String)
    Matchup = Switch(CityName = "London", "English", CityName _
                    = "Rome", "Italian", CityName = "Paris", "French")
End Function

• Top N Records in Query
• Attachment field in Access2007
• Embedded Macros in Access2007
• Attachment Field in Access2007
• PrimaryKey usage with many fields

But, when you pull this field into a Query with some filter criteria then the autonumber Field contents may not be in consecutive order. If you have planned to use the autonumber field on the report for sequence numbers then you have to look for alternatives. As far as the Report is concerned this is not an issue, you can easily create a Textbox in the Detail Section of the Report and type the expression =1 in the Control Source property and set the Running Sum property value to Yes.

If the the Query is used as a Data View file or create an output table from the filtered data with proper sequence numbers then we have to think of devising some tricks to achieve that. I have already created a Function for generating Sequence Numbers for filtered data in a Query column in an earlier Blog Post and you can have it from the link: Auto-Numbering in Query Column.

The above was only an introduction to what we are going to do here.  What we have seen in the above Auto-numbering example is assigning sequence numbers for the entire query output records.  But, what if we want separate sequence numbers for each category of records or records belongs to a particular group?

For example: In a School the Headmaster would like to know who is the highest rank holder in each Subject in a particular Class/School.  Or to find top 5 State-level student Rank holders of the Schools in each Subject.  Or you have invited quotations for supplying electronic goods and you would like to know item-wise lowest Quotes from among several suppliers.

To do this we can write a VBA Function to work on a report source table with a new data field: Rank, to write out the rank list values.  First, the Data Table must be prepared by combining information from input Tables/Queries etc.  A sample image of a Students’ Table with several subjects is given below, ready for running our RankList() Program.

Our task is to organize the above data in a specified order and assign Rank numbers as 1,2,3 etc. based on the highest values in the Score field (sorted in Descending order) for each group of subjects in the Event field (sorted in Ascending order).  This rank list is prepared for Class No.2 involving several schools in the area.

Table Name: SchoolTable

Sorting Order: Event (Ascending), Score (Descending), School (Ascending) – School field sorting optional

Function Call Syntax: RankList(TableName, Primary Sorting Field, Value Field, Optional Third Sorting Field)

Sample Function Call: RankList(“SchoolTable”,”Events”,”Score”,”School”)

The RankList() Function Code is given below:

Public Function RankList(ByVal TableName As String, _
                         ByVal Grp1Field As String, _
                         ByVal ValueField As String, _
                         Optional ByVal Grp2Field As String)
'-----------------------------------------------------------------
'Preparing Rank List
'Author : a.p.r.pillai
'Date   : August 2011
'Rights : All Rights Reserved by www.msaccesstips.com
'Remarks: Free to use in your Projects
'-----------------------------------------------------------------
'Parameter List:
'TableName  : Source Data Table
'Grp1Field  : Category Group to Sort on
'ValueField : On which to determine the Rank Order
'Grp2Field  : Sorted on for values with the same rank number
'-----------------------------------------------------------------
Dim db As Database, rst As Recordset, curntValue, prevValue
Dim srlRank As Byte, curntGrp1, prevGrp1
Dim prevGrp2, curntGrp2
Dim fld As Field, tbldef As TableDef, idx As Index
Dim FieldType As Integer

On Error Resume Next

Set db = CurrentDb
Set rst = db.OpenRecordset(TableName, dbOpenTable)

'Check for presence of Table Index "MyIndex"
'if not found then create
rst.Index = "MyIndex"

If Err > 0 Then
   Err.Clear
   On Error GoTo RankList_Err

Set tbldef = db.TableDefs(TableName)
Set idx = tbldef.CreateIndex("MyIndex")

FieldType = rst.Fields(Grp1Field).Type
Set fld = tbldef.CreateField(Grp1Field, FieldType)
idx.Fields.Append fld

FieldType = rst.Fields(ValueField).Type
Set fld = tbldef.CreateField(ValueField, FieldType)
fld.Attributes = dbDescending ' Line not required for sorting in Ascending
idx.Fields.Append fld

FieldType = rst.Fields(Grp2Field).Type
Set fld = tbldef.CreateField(Grp2Field, FieldType)
idx.Fields.Append fld

rst.Close

tbldef.Indexes.Append idx
tbldef.Indexes.Refresh
Set rst = db.OpenRecordset(TableName, dbOpenTable)
rst.Index = "MyIndex"
End If

curntGrp1 = rst.Fields(Grp1Field)
prevGrp1 = curntGrp1
curntValue = rst.Fields(ValueField).Value
prevValue = curntValue

Do While Not rst.EOF
     srlRank = 1
     Do While (curntGrp1 = prevGrp1) And Not rst.EOF
       If curntValue < prevValue Then
          srlRank = srlRank + 1
       End If
          rst.Edit
          rst![Rank] = srlRank
          rst.Update
          rst.MoveNext
          If Not rst.EOF Then
             curntGrp1 = rst.Fields(Grp1Field)
             prevValue = curntValue
             curntValue = rst.Fields(ValueField).Value
          End If
     Loop
     prevGrp1 = curntGrp1
     prevValue = curntValue
Loop
rst.Close
'Delete the Temporary Index
tbldef.Indexes.Delete "MyIndex"
tbldef.Indexes.Refresh

Set rst = Nothing
Set db = Nothing

RankList_Exit:
Exit Function

RankList_Err:
MsgBox Err & " : " & Err.Description, , "RankList()"
Resume RankList_Exit

End Function

In the first part of the Program we check for the presence of an Index ‘MyIndex’ in the input table. If not found then creates the Index, for temporary use.  After creating the rank list on the table we delete the temporary Index “MyIndex” from the table.

Result of the run of RankList("SchoolTable","Events","Score","School") Function is given below.  Check the Rank field values based on the Score field values of Event field.

The first two ranks for Accounting are obtained by City View School, 3rd rank by Krum School, 4,5 & 6 awarded to Holiday School.  Seventh rank is shared by City View and Holiday Schools.

Similarly, Current Events and Social Studies are also listed according to their order of ranks.

• Embedded Macros in Access2007
• Attachment Field in Access2007
• PrimaryKey usage with many fields
• Percentage on Report Summary
• Embedded Macros in Access2007

Image Source: www.dgreetings.com

പുന്നെല്ലടകൊണ്ടടപ്രഥമന്‍ – അതില്‍
പൊന്തിക്കിടക്കുന്ന നാളികേരത്തുണ്ട്
നെയ്യില്‍ വറുത്തിട്ട മുന്തിരി.. അണ്ടിപ്പരിപ്പുകള്‍
കണ്ണൊന്നിറുക്കി ; നാക്കിലയില്‍ കിടന്നെന്നെ
കൊതിപ്പിക്കും പായസങ്ങള്‍….

Source: http://www.greetings.prokerala.com/

Wishing you Bountiful of Joy and abounding prosperity on the occasion of Thiruvonam Day.

HAPPY ONAM!

Let us take an example of a Date-of-Birth (or an Invoice Date) data entry field on a Form.  If we leave this field open to accept any date value then it is likely that the user may make mistakes like entering a future date.  To prevent such eventualities we must enable the built-in Validation checks on the value entered into the date field and warn the user about the mistake and force him to enter a valid value.

We can do this by setting Validation Rule and Validation Text property values of the Date Field.  The Validation Rule property of the date field can be set with the expression: <Date() to accept date values earlier than Today in the date-of-birth field. But, this expression is good only if we are prepared to accept date-of-birth values earlier than 100 years or more, otherwise we must set a lower bound value too, like >=(DateAdd(“yyyy”,-100,Date()) and <Date().  To warn the user about the data entry error, the Validation Text property can be set with a message text like: Future date is invalid and Age Limit 100 years.  This is better if you implement it on the Table itself rather than on the Form.

It is equally important that Users are kept away from modifying objects like Forms, Queries, Reports, Macros and VBA Programs.  This is where we consider implementing User-level Security in Microsoft Access.  User-level security feature is available in Microsoft Access2003 or earlier versions only.

Another way of preventing users from straying out is to create Custom Menus and Custom Tool bars for the Application and disable all built-in Menus and Toolbars, so that users are not able to get into object designs through the built in Menus.  If you have designed customized Menus and Toolbars then you can disable the built-in Menus by removing the Check-marks in the Access Options.

Caution: Take a backup of the database before making the following changes otherwise you may not be able to get back into the database for making design changes yourself later.

Select Office Button – -> Access Options – -> Current Database – -> Ribbon and Toolbar Options

Remove check-marks from the following options:

• Allow Full Menus
• Allow Default Shortcut Menus
• Allow Built-in Toolbars

After removing the check-marks you must close and reopen the database. Now, the customized Menus and Toolbars you have created are only available to the User. But, unfortunately even now your database objects Forms, Reports etc. are not safe from unauthorized changes. It is true that they cannot right-click on an object in the Navigation Pane and go into design view, but they can if they select the VBA Module’s view from the Navigation Pane, browse for a Form/Report, select it and then select View Object option.

In the VBA Navigation Pane, Forms and Reports with VBA Sub-Routines behind them are visible to the Users. You can hide those objects by setting their Hide Option by right-clicking on the database Navigation Pane. If you don’t want Users to go into the Module View, through the Navigation Pane then you may remove the check-mark from the Display Navigation Pane option along with the Menu options explained above. Unless the User is too smart you can consider your Database Objects safe, but not safe enough from a smarter one. If some one familiar with the Keyboard Shortcuts can open the VBA Module wide open by pressing ALT+F11. You can write the rest of the story yourself from there.  Even If you keep the Navigation Pane of the VBA window hidden it can be opened by clicking on the Object browser button on the toolbar. 

Since, the User-level Security is not available in Access2007 and latter versions these are some of the methods available to you to implement security within an Access Database.

Once you remove the Full Menus Option it will be difficult for you to get back into the database for making changes to Forms, Reports etc. That’s why I said to take a back-up, to be on the safe side.

Even during design time make it as a regular practice to take back-ups of the database, to save the work done so far, before starting with latest changes. If the database somehow got corrupted (or deleted by mistake) at any stage of design time you are safe from totally loosing your database.

If you want the Full menus back again we can play a small trick to get back into the database and put the check-mark back into the Allow Full Menus Option, without going through directly from Office Button Menu as explained above.

1. Open the database.
2. Press ALT+F11 to display the VBA Window
3. Press CTRL+G to display the Debugging Window (Immediate Window).
4. Type the following command in the Debug window and press Enter Key:

   CurrentDb.Properties("AllowFullMenus").Value = True

5. Close and re-open the database again. 

Now, you can approach Access Options through Office Button (top left corner) and make changes to Options there.

• Attachment Field in Access2007
• PrimaryKey usage with many fields
• Percentage on Report Summary
• Embedded Macros in Access2007
• Report Design in Access2007

If you have already converted .mdb database into .accdb format and lost all user-level security settings then you are not totally lost with the database. If you have a backup of the earlier version database then you are lucky. All you have to do is to restore the database from backup and use it in Access2007 with User-level security intact.  If you lost the backups too then you can save the Access2007 version database into an earlier Version 2002-2003 or 2000, by using the Save As…  option from the Office Menu (top left corner menu) and select an appropriate .mdb database format and save the active Database as a new copy.

This will not restore the User-level security settings.  You have to restore it manually from scratch by assigning access rights to each and every database object at User-Groups or individual User level.

In either case you must Join the Workgroup Information File (a database with .mdw file extension) from Access2007, to attach your database Users/Groups to Access 2007 to use with your .mdb databases or to implement new security profiles on them.

When you open an .mdb database in Access2007 the Users and Permissions Menu is visible under Database Tools.  But, your database Users or User-groups will not be visible under this option unless you Join the Wrokgroup Information File, you were using in earlier version of Access.

In Access2003 there is an option under Tools—>Security to run the Workgroup Administrator program to Create/Join a Workgroup Information File.  In Microsoft Access2000 this program is located in the Language Folder (…\1033 for U.S. English) of MS-Office C:\Program Files\Microsoft Office\Office\1033\WrkgAdm.exe to run and Join the Workgroup Information File.

But, in Microsoft Access2007 none of these options are available, except running the following command from VBA:

DoCmd.RunCommand acCmdWorkgroupAdministrator 

You can run this command from the Debug Window (Immediate Window, Alt+F11 then Ctrl+G to display) manually or from a Command Button Click Event Procedure and Create a new Workgroup Information File or Join an existing one on Server.

Once you Join the Workgroup Information File you can start using the .mdb files with their User-level security in Microsoft Access2007 or restore the lost security settings manually.

• PrimaryKey usage with many fields
• Percentage on Report Summary
• Embedded Macros in Access2007
• Report Design in Access2007
• Memo Field Text Formatting

DoCmd.OpenForm "myForm", acNormal, , "EmployeeID Between 5 AND 10" command line in VBA) or Filter by Selection on Form or use a Query as Record Source and so on.

But, it is very unlikely  that someone think of using the Filter Property of a Table directly to filter records when the Table is open in Datasheet View.  If you are working with someone else project and found a table showing only few records in datasheet view but you are told that the table suppose to have hundreds of records in it and want to find out what happened to the rest of the records, then read on.

We will explore how this trick works on a Table, for a change.  If you ever tried to set a Filter condition directly on a Form then you don’t need any extra help to do this on your own.  To try out this we need some ready made data from Northwind.accdb sample database.  You may try it out with your own table as well.

1. Import the Order Details  Table from Northwind.accdb sample database.
2. Open the Table in Design view.
3. Press F4 to display the Property Sheet of the Table.

   

   Table Property Sheet View

4. Find the Filter Property and type [Order ID] Between 35 AND 45 into the property (in Access2007). Type [OrderID] Between 10249 AND 10251 in earlier Access Versions.
5. Set the Filter On Load property value to Yes.
6. Save and close the Table Structure.
7. Open the Table in Datasheet View to see the Filter in action.

The output records displayed are only of Order IDs between 35 and 45.  If you design a Quick Form or Report from this Table the Record Source property will be set with an SQL SELECT statement with the WHERE condition inserted from the Filter Property settings from the Table.  But, if you modify the Filter condition on the Table later don’t expect to reflect that change on the Record Source SQL of Report or Form automatically.

Like anything else in Microsoft Access If you would like to automate this through VBA, to change the filter criteria with the click of a button then here it is for you.  But, there is a small problem which I will tell you later so that you will know how important it is.  After all it is about setting a simple filter condition on the Filter Property of the Table Structure.

We can address the Filter Property of a Table in VBA either through the front-door approach or through the back-door method, so to speak.  The front-door approach is addressing the Filter Property through the TableDef.Property.Filter path and the back-door approach is addressing through Container.Documents.Properties.Filter path.  As you can see the second method is little bit lengthy, that is why I call it back-door method.  We will try examples of both methods.

The second approach is very useful when working with Forms or Reports, like taking a list of all Forms/Reports or want to change the name of a Form etc. You can refer an earlier blog post that creates a User-defined Property (Custom Property) to save values in it for opening a Form with last-worked record to continue work from that record onwards, click here to find out more about it.

Example-1:

1. Copy and Paste the following VBA Code into a Standard Module of your Database.

   Public Function TableFilter1(ByVal OrderStart As Long, ByVal OrderEnd As Long)
   Dim db As Database
   Dim Tbldef As TableDef
   
   Set db = CurrentDb
   
   Set Tbldef = db.TableDefs("Order Details")
   Tbldef.Properties("Filter").Value = "[Order ID] >=" & OrderStart & " AND [Order ID] <=" & OrderEnd
   Tbldef.Properties("FilterOnLoad").Value = True
   db.TableDefs.Refresh
   
   End Function

2. Run the above sample Code from the Debug Window or from a Command Button Click Event Procedure like the sample run given below:

TableFilter1 35,45

NB: The above Code and sample run is given for Order Details Table of Access2007.  If you are using an earlier Access Version then change the [Order ID] name to [OrderID] (i.e. without a space between Order and ID) and in the sample run type TableFilter1 10249, 10251 instead of 35,45 for OrderID range values.

If you have not tried out the manual filter method explained above or removed the filter criteria setting from the Filter Property then you will run into problems with the above program reporting an Error message stating that the Filter Property not found.

When you implement the VBA method see that an initial criteria setting is set in the Filter property of the Table.  Without the criteria setting the Filter Property will not be visible in VBA.

Example-2:

Copy and Paste the following VBA Code into the Standard VBA Module and run the Code in the same way as Example-1 with different set of OrderIDs:

Public Function TableFilter2(ByVal OrderStart As Long, ByVal OrderEnd As Long)
Dim db As Database, ctr As Container, doc As Document

Set db = CurrentDb

Set ctr = db.Containers("Tables")
Set doc = ctr.Documents("Order Details")
doc.Properties("Filter").Value = "[Order ID] >=" & OrderStart & " AND [Order ID] <=" & OrderEnd
doc.Properties("FilterOnLoad").Value = True
doc.Properties.Refresh

End Function

• Percentage on Report Summary
• Embedded Macros in Access2007
• Report Design in Access2007
• Memo Field Text Formatting
• Sub-Query in Query Column Expression

The DLookup(“TaxRate2005”,”tblTaxRates”,”[Product Code] = ‘” & [ProductCode] & “’”) Function is used in a Query Column to pick up Sale Tax Rate from the tblTaxRates Table, for each item sold, for calculating the Sale Tax Value for the actual Sale value.  The Tax Rate will change every year during annual budgeting of the government.  The Company maintains the history of these changes and adds a new tax-rate-field with Year as Suffix to the tblTaxRates Table like: TaxRate2005, TaxRate2006, TaxRate2007 etc.  Take a look at the sample image given below:

The Query Column name is TaxRate where the Dlookup() Function is inserted, irrespective of TaxRate2005 or TaxRate2006 or TaxRate2007 is selected in the function parameter like: TaxRate:Dlookup(“TaxRate2005”,”tblName”,”Criteria”).  When we design a report we can use the report control name as TaxRate and no need to modify every time.

Check the sample Query result image given below:

Now, assume that there are Orders placed during December with the applicable Tax Rate at that time. There are Orders placed for materials immediately after the budget implementation with revised sale tax rate.  We have to prepare some invoices with previous year sale tax rates and others with current year rates.  That means the Dlookup() function will look like Dlookup(“TaxRate2005”,” “,” “) for previous year and Dlookup(“TaxRate2006”,” “, “ “) for current year.  The table name and criteria part is omitted for clarity. As you can see the first parameter of the function must be changed every time for printing previous year and current year invoices.

We cannot ask the User to go in and change the Query design.  There must be a way to define that particular parameter of the function dynamically to refer to different tax rate columns on the tblTaxRates.  The solution is very simple, design a small Form with a Text Box and a Command button and let the user type the tax rate field name  in the Text Box (or create a Combo Box if required) and click the Command Button to refresh the Query and open the Report that uses this Query as record source.  Sample image of the Query parameter Form is given below:

The Textbox name is Tax on the above form.  With that in mind our Dlookup() function in the Order Details Query column will look like as given below:

TaxRate:DLookup([Forms]![InvoiceParam]![Tax],”tblTaxRates”,”[ProdCode]= '” & [Product Code] & “'”)

In the criteria part the ProdCode field of tblTaxRate table should match with the (Product Code) field of the Products Table linked with the Order Details Table to return the tax rate value for each item on the Order Details table.

The sample SQL of the Query is given below:

SELECT [Order Details].[Order ID],
 Products.[Product Code],
 Products.[Product Name],
 [Order Details].Quantity,
 [Order Details].[Unit Price],
 [Quantity]*[Unit Price] AS SaleValue,
 Val(DLookUp([Forms]![InvoiceParam]![Tax],"TaxRates","[ProdCode]='" & [Product Code] & "'")) AS TaxRate,
 [SaleValue]*[TaxRate] AS SaleTax,
 [SaleValue]+[SaleTax] AS TotalSaleValue
FROM Products INNER JOIN [Order Details] ON Products.ID = [Order Details].[Product ID];

The Command Button Click Event Procedure can run the following Code to open the Sales Invoice Report after refreshing the change on the Form:

Private Sub cmdRun_Click()
Me.Refresh
DoCmd.OpenReport "SalesInvoice", acViewPreview
End Sub

• Embedded Macros in Access2007
• Report Design in Access2007
• Memo Field Text Formatting
• Sub-Query in Query Column Expression
• GetRows() Function and Exporting Data

You can design a report in minutes. Or you can design the same report giving personal attention to each and every control on the report for their placement, control size, font size, highlighting, heading, footer, summary lines and so on. It may take several hours before you are satisfied with the idea of presenting the report to the boss, stand back and look for the sign of appreciation appearing on his face.

Talking of controls and enhancements whey can’t we place a Watermark (a Company Logo or Company Name) on the Report Background to give the report a touch of class? It will not take much to do that. If you have an Image of your Company Logo (in .bmp format) with a very light gray scale color (like the image given below) you can easily implement this idea on your Report.

1. Open the Report in Design View.
2. Display the Report’s Property Sheet (F4).
3. Look for the Picture Property and click on the property to select it.
4. Click on the Build button (. . . at the right end of the property) to browse for the Watermark image on the disk and select it.
5. With the following three property settings of the Report you can display and print the watermark image in various ways:
   • PictureAlignment = 2 (center)
   • PictureTiling = False
   • PictureSizeMode = 3 (zoom)

When you load the Watermark picture in the background, with the above property settings, the Report Print Preview looks like the image given below:

Print the Report on Printer or convert into MS-Access Snapshot format (.snp) or into PDF.

The above manual work made easier for any Report with the VBA Code given below:

Public Function ReportWaterMark()
Dim rpt As Report, txtRpt As String
Dim imgPath As String

txtRprt = ""
imgPath = ""

Do While txtRpt = "" Or imgPath = ""
  If txtRpt = "" Then
   txtRpt = Nz(InputBox("Give Report Name:", "Report Water Mark"), "")
  End If
  If imgPath = "" Then
   imgPath = Nz(InputBox("Watermark Image PathName:", "Report Water Mark"), "")
  End If
Loop

DoCmd.OpenReport txtRpt, acViewDesign

Set rpt = Reports(txtRpt)
With rpt
    .Picture = imgPath
    .PictureAlignment = 2
    .PictureTiling = False
    .PictureSizeMode = 3
End With
DoCmd.Close acReport, txtRpt, acSaveYes
Set rpt = Nothing

DoCmd.OpenReport txtRpt, acViewPreview

End Function

Copy and paste the above code into a Standard VBA Module and save the code.  You can run this program from a Command Button Click Event Procedure like:

Private Sub cmdWMark_Click()
    ReportWaterMark
End Sub

When you run the main program it will prompt for the Report Name and for the Watermark Image location with image name. You must note down these information somewhere before you attempt to run the program. You need to run this program only once for a report. The image stays as the backgroud picture on the report till you run the program again to change the image.

Try the following property settings to see how they appear on the Report Print Preview:

    .PictureAlignment = 0
    .PictureTiling = True
    .PictureSizeMode = 0

    .PictureAlignment = 2
    .PictureTiling = False
    .PictureSizeMode = 1

• Report Design in Access2007
• Memo Field Text Formatting
• Sub-Query in Query Column Expression
• GetRows() Function and Exporting Data
• Create Menus with Macros-2

Let us try one or two conversion examples.

Example-1: mmddyyyy

x = 07092011 or x=”07092011”

y = July 09, 2011 (internal representation of the actual date number is 40733)

Conversion expression:

y = DateSerial(Right(x,4),Left(x,2),Mid(x,3,2))

OR

y = DateValue(Left(x,2) & "-" & Mid(x,3,2) & "-" & Right(x,4))

Depending on the input date format (Asian, USA or ANSI) usage order of Left(), Right() and Mid() functions in the DateSerial() or DateValue() Functions will change.  But, writing the above expressions every time when we put the data into Queries is not advisable and time consuming too.  The easiest way to overcome this is to create User-defined functions with the above expressions and call the function from the Query Column or from anywhere these date numbers are involved in calculations or comparisons etc.

Let us create the following simple Functions that will make our life easier with these numbers on the long run.

Function: DMY_N2D(ByVal ddmmyyyy as Variant) As Date 

Converts from date number in ddmmyyyy format into a real date number.  The input number can be in Long Number format (09072011 or 9072011) or in text format “09072011”.  _N2D stands for Number to Date.  The first three characters of the function name DMY indicates the order of Day, Month & Year elements of the input date number.

Public Function DMY_N2D(ByVal ddmmyyyy As Variant) As Date
'------------------------------------------------------------------
'Converts Numbers (in ddmmyyyy format) 09072011 into a Date Number
'Author : a.p.r.pillai
'Date   : Sept. 1999
'Rights : All Rights Reserved by www.msaccesstips.com
'------------------------------------------------------------------
Dim strN2D As String

On Error GoTo DMY_N2D_Err

strN2D = Format(ddmmyyyy, "00000000") ' add 0 at the left side, if 7 digit number

DMY_N2D = DateSerial(Right(strN2D, 4), Mid(strN2D, 3, 2), Left(strN2D, 2))

DMY_N2D_Exit:
Exit Function

DMY_N2D_Err:
MsgBox Err.Description,, "DMY_N2D()"
Resume DMY_N2D_Exit
End Function

When the input Number is in mmddyyyy format:

Public Function MDY_N2D(ByVal mmddyyyy As Variant) As Date
'------------------------------------------------------------------
'Converts Numbers (in mmddyyyy format) 07092011 into a Date Number
'Author : a.p.r.pillai
'Date   : Sept. 1999
'Rights : All Rights Reserved by www.msaccesstips.com
'------------------------------------------------------------------
Dim strN2D As String 

On Error GoTo MDY_N2D_Err 

strN2D = Format(mmddyyyy, "00000000") ' add 0 at the left side, if 7 digit number

MDY_N2D = DateSerial(Right(strN2D, 4), Left(strN2D, 2), Mid(strN2D, 3, 2)) 

MDY_N2D_Exit:
Exit Function 

MDY_N2D_Err:
MsgBox Err.Description,, "MDY_N2D()"
Resume MDY_N2D_Exit
End Function

When the date number is in yyyymmdd (ANSI) format:

Public Function YMD_N2D(ByVal yyyymmdd As Variant) As Date
'------------------------------------------------------------------
'Converts Numbers (in yyyymmdd format) 20110709 into a Date Number
'Author : a.p.r.pillai
'Date   : Sept. 1999
'Rights : All Rights Reserved by www.msaccesstips.com
'------------------------------------------------------------------
Dim strN2D As String

On Error GoTo YMD_N2D_Err

YMD_N2D = DateSerial(Left(strN2D, 4),Mid(strN2D, 5, 2),Right(strN2D, 2))

DMY_N2D_Exit:
Exit Function

YMD_N2D_Err:
MsgBox Err.Description,, "YMD_N2D()"
Resume YMD_N2D_Exit
End Function

• Memo Field Text Formatting
• Sub-Query in Query Column Expression
• GetRows() Function and Exporting Data
• Create Menus with Macros-2
• Create Menus with Macros