Wave Shaped Reminder Ticker ~ LEARN MS-ACCESS TIPS AND TRICKS

Introduction.

We have already seen how to create and install a Reminder Ticker that runs in a straight line on the Main Screen. We could do this with a few lines of VBA Code and a Label on the Main Screen. We will try something different this time. This ticker runs in a Zigzag form. An image of a sample run of this method is given below

To create this Ticker we need a series of labels arranged in a wavelike form and each one of them must be named in such a way that we could address them easily in code. A sample design is given below:

Automating the Labels Creation

There are about 42 identical Labels to create. Even if we create them once manually, arranging them in this fashion is not an easy task. But we can do it with a small Program. The Program creates a new Form and creates all 42 Labels, and gives names like lbl1 to lbl42, changes other Properties as shown above.

Copy the following Code into a Global Module of your Database and save it.

Public Function ZIGZAG()
'-----------------------------------------------------------
'Author  :  a.p.r. pillai
'Date    :  01/10/2008
'URL     :  www.msaccesstips.com
'All Rights Reserved by www.msaccesstips.com
'-----------------------------------------------------------
Dim frm As Form, ctrl As Label, t As Long, lngleft As Long
Dim lngwidth As Long, lngheight As Long, lngtop As Long
Dim j As Integer, k As Integer, h As Long, G As Long

h = 30: G = 0: t = 0
lngwidth = 0.1146 * 1440
lngheight = 0.2083 * 1440
lngtop = 1 * 1440
lngleft = 0.16667 * 1440
Set frm = CreateForm
For j = 1 To 42
Set ctrl = CreateControl(frm.Name, acLabel, acDetail, , , lngleft, lngtop, lngwidth, lngheight)
lngleft = lngleft + lngwidth
With ctrl
    .Name = "lbl" & j
    .FontName = "Tahoma"
    .FontSize = 8
    .Caption = ""
    .BackStyle = 0
    .ForeColor = 255
 End With
 Next
G = 0
For j = 1 To 3
     For k = 1 To 7
        G = G + 1
        Set ctrl = frm.Controls("lbl" & G)
        With ctrl
            .Top = .Top - (h * k)
        End With
        DoEvents
     Next
    t = frm.Controls("lbl" & G).Top
     For k = 1 To 7
         G = G + 1
        Set ctrl = frm.Controls("lbl" & G)
        With ctrl
            .Top = t + (h * 1)
        End With
        t = frm.Controls("lbl" & G).Top
        DoEvents
    Next
Next
End Function

You can run the above Code directly by placing the cursor in the middle of the Code and pressing the F5 Key, or running from a Command Button's On Click Event Procedure or a Macro.
Every time when the code is run it will create a new Form with the Labels arranged in a zigzag form. After you create it once, export that Form to your other Projects where you want to install the ZigZag Ticker. Or better you may install the code in a Common Library Database and run it from your new project, after attaching the Library File to your Project.
Placement of the Ticker Labels.
After creating the Labels, click somewhere outside the Labels and drag over them so that all the Labels are selected without disturbing the arrangement of the labels.
Select Copy from Edit Menu.
Open the Main Switch Board (Control Form) in Design View and Paste them.
When all the labels are still in the selected state drag and place the Labels into a position where you want the Ticker to appear on the Form.
We have two more Sub-Routines which are run from the Form_Load() and Form_Timer() Event Procedures. In the Form_Load() Event Procedure, we can create a Text Message in a String either with a constant value or with Field Values from a Table/Query that provide useful information to display to the User as a reminder. Refer to the earlier example Reminder Ticker Form which uses information from within the Application for Reminder.
Formatting Ticker Text
The Form_Timer() Event Procedure will control the Display of Label values shifting one character at a time in succeeding labels giving it a sense of motion.

Copy and Paste the following Sub-Routines into the Form Module where you have pasted the above labels.

Option Compare Database
Option Explicit
Dim txt As Variant

Private Sub Form_Load()
    txt = Space(42) & UCase("Excellence is not a matter of chance. It is a matter of Change. It is not a thing to be waited for. It is a thing to be achieved.")
    Me.Timerinterval=250
End Sub

See that the Dim txt As Variant is placed in the Global Area of the Module, which is referenced from the Form_Load() and Form_Timer() Event Procedures.

Private Sub Form_Timer()
Dim x As String, k As String, j As Integer, ctrl As Control

  x = Left(txt, 1)
  txt = Right(txt, Len(txt) - 1)
  txt = txt & x
  k = Left(txt, 42)
For j = 1 To Len(k)
    Set ctrl = Me.Controls("lbl" & J)
    Ctrl.Caption = Mid(k, j, 1)
Next
End Sub

Disable Ticker on inactive Form

The following lines of code are useful if you plan to disable the ticker when the Main Form is inactive and run it when the Main Form is active again so that other processes are not interrupted by the Ticker.

Private Sub Form_Deactivate()
   Me.TimerInterval = 0
End Sub

Private Sub Form_Activate()
   Me.TimerInterval = 250
End Sub

Download

Download Demo Database Access2007.zip

Download Demo Database Access2002-03.zip

LEARN MS-ACCESS TIPS AND TRICKS